Wysyłanie poczty przez SMTP w Perlu

Question

Próbuję wysłać pocztę przez SMTP w Perlu.

Napisałem scenariusz do tego.

#!perl 
use warnings; 
use strict; 
use Net::SMTP; 

my $smtpserver = 'server'; 
my $smtpport = 25; 
my $smtpuser = 'username'; 
my $smtppassword = 'password'; 

my $smtp = Net::SMTP->new($smtpserver, Port=>$smtpport, Timeout => 10, Debug => 1); 
die "Could not connect to server!\n" unless $smtp; 

$smtp->auth($smtpuser, $smtppassword); 
$smtp->to('mymail@gmail.com'); 
$smtp->data(); 
$smtp->datasend("To: mymail\@gmail.com\n"); 
$smtp->quit; 

Kiedy uruchomić ten skrypt, moje wyjście jest jak następuje:

Net::SMTP>>> Net::SMTP(2.31) 
Net::SMTP>>> Net::Cmd(2.29) 
Net::SMTP>>>  Exporter(5.65) 
Net::SMTP>>> IO::Socket::INET(1.31) 
Net::SMTP>>>  IO::Socket(1.32) 
Net::SMTP>>>  IO::Handle(1.31) 
Net::SMTP=GLOB(0x273faf0)<<< 220 server GMX Mailservices E 
Net::SMTP=GLOB(0x273faf0)>>> EHLO localhost.localdomain 
Net::SMTP=GLOB(0x273faf0)<<< 250-server GMX Mailservices 
Net::SMTP=GLOB(0x273faf0)<<< 250-8BITMIME 
Net::SMTP=GLOB(0x273faf0)<<< 250-ENHANCEDSTATUSCODES 
Net::SMTP=GLOB(0x273faf0)<<< 250-SIZE 
Net::SMTP=GLOB(0x273faf0)<<< 250-AUTH=LOGIN PLAIN 
Net::SMTP=GLOB(0x273faf0)<<< 250-AUTH LOGIN PLAIN 
Net::SMTP=GLOB(0x273faf0)<<< 250 STARTTLS 
Net::SMTP=GLOB(0x273faf0)>>> RCPT TO:<mymail@gmail.com> 
Net::SMTP=GLOB(0x273faf0)<<< 503 5.5.1 MAIL first {mp-eu001} 
Net::SMTP=GLOB(0x273faf0)>>> DATA 
Net::SMTP=GLOB(0x273faf0)<<< 503 5.5.1 MAIL first {mp-eu001} 
Net::SMTP=GLOB(0x273faf0)>>> To: mymail@gmail.com 
Net::SMTP=GLOB(0x273faf0)>>> . 
Net::SMTP=GLOB(0x273faf0)<<< 502 5.5.2 Unimplemented {mp-eu001} 
Net::SMTP=GLOB(0x273faf0)>>> QUIT 
Net::SMTP=GLOB(0x273faf0)<<< 502 5.5.2 Unimplemented {mp-eu001} 

nie mam wystarczająco dużo informacji na temat Perl i SMTP, więc nie mogłem zrozumieć tego błędu.

Jak mogę to rozwiązać?

Answer 1

Musisz rozpocząć sesję SMTP (po autoryzacji, jeśli to konieczne) poleceniem MAIL podając adres e-mail nadawcy. Dlatego odpowiedzi mówią "MAIL first" (5xx to odpowiedź błędu). Więc:

$smtp->auth($smtpuser, $smtppassword); 
$smtp->mail('sender@example.com'); 
$smtp->to('mymail@gmail.com'); 

Ale jeśli nie jesteś ekspertem SMTP, to dlaczego nie wykorzystać moduł wyższego poziomu jak Email::Sender zamiast niskiego poziomu Net::SMTP?

use strict; 
use warnings; 

use Email::Sender::Simple qw(sendmail); 
use Email::Sender::Transport::SMTP(); 
use Email::Simple(); 
use Email::Simple::Creator(); 

my $smtpserver = 'server'; 
my $smtpport = 25; 
my $smtpuser = 'username'; 
my $smtppassword = 'password'; 

my $transport = Email::Sender::Transport::SMTP->new({ 
    host => $smtpserver, 
    port => $smtpport, 
    sasl_username => $smtpuser, 
    sasl_password => $smtppassword, 
}); 

my $email = Email::Simple->create(
    header => [ 
    To  => 'mymail@gmail.com', 
    From => 'sender@example.com', 
    Subject => 'Hi!', 
    ], 
    body => "This is my message\n", 
); 

sendmail($email, { transport => $transport }); 

Answer 2

Narzeka na brak polecenia SMTP MAIL FROM:. Nie patrząc na jakiejkolwiek dokumentacji, to myślę, że to wyglądać mniej więcej tak $smtp->from('you@example.net') Jak @cjm pisze, trzeba $smtp->mail('you@example.net');

prawda, wydaje się nieco głupie musiał podać nazwę użytkownika Bezpośrednio po uwierzytelnieniu , ale ma sens z punktu widzenia kompatybilności historycznej i wstecznej (specyfikacja STARTTLS ESMTP może po prostu określać, co należy zrobić, aby uwierzytelnić, następnie reszta sesji odbywa się tak jak w zwykłym SMTP po wykonaniu uwierzytelniania). Dla użytkownika Net::SMTP ma to sens, aby uchronić Cię przed tymi szczegółami implementacji.

Answer 3

Btw - choć nieco późno, w każdym razie dla przyszłych czytelników, czy rzeczywiście recv pocztę?

Na dołączonym wyjściu nie ma błędów. Włączono debugowanie (Debug => 1) w swoim konstruktorze. Komunikaty te znikną po ustawieniu wartości na 0. Zaletą korzystania z protokołu SMTP jest to, że jest on dołączony do instalacji w magazynie. Nie ma potrzeby dodawania modułów.

Answer 4

Niestety, w (bardzo) pod koniec 2014 r. Net :: SMTP :: SSL nie przejdzie 1 z 1 testów instalacji, w związku z tym serwer sieciowy (i każdy inny) jest nieosiągalny. Bez instalowania mojego własnego serwera pocztowego, jedynym sposobem, jaki mogę znaleźć, aby wysłać pocztę z Perla, jest OLE do Outlooka. Outlook będzie wtedy wykorzystywał swoje połączenia, aby wszystko działało.

Mam nadzieję, że ktoś może mi udowodnić, że się mylę.

Answer 5

Oto zaktualizowana wersja skryptu cjm, który aktualnie współpracuje z Gmailem przy użyciu STARTTLS (nie testowany z innymi usługami SMTP) Używa Email :: Sender :: Transport :: SMTPS zamiast Email :: Sender :: Transport :: SMTP

konta Gmail będzie mieć „Dostęp dla mniej bezpiecznych aplikacji” dozwolony („włączony”) - gdzie „mniej bezpieczne” nie znaczy niezaszyfrowane, to po prostu nie wydaje się oznaczać za pomocą OAuth 2.0

use strict; 
use warnings; 

use Email::Sender::Simple qw(sendmail); 
use Email::Sender::Transport::SMTPS; 
use Email::Simple(); 
use Email::Simple::Creator(); 

my $smtpserver = 'smtp.gmail.com'; 
my $smtpport = 587; 
my $smtpuser = 'user@gmail.com'; 
my $smtppassword = 'password'; 

my $transport = Email::Sender::Transport::SMTPS->new({ 
    host => $smtpserver, 
    ssl => 'starttls', 
    port => $smtpport, 
    sasl_username => $smtpuser, 
    sasl_password => $smtppassword, 
    debug => 1, 
}); 


my $email = Email::Simple->create(
    header => [ 
    To  => 'user@example.com', 
    From => 'whatever@gmail.com', 
    Subject => 'Hi!', 
    ], 
    body => "This is my message\n", 
); 

sendmail($email, { transport => $transport }); 

Answer 6

W przypadku usług pocztowych korzystających z programu STARTTLS najlepiej jest użyć nowszego modułu NET :: SMTPS.Wypróbuj następujący kod:

my $msg = MIME::Lite ->new ( 
From => 'from@bellsouth.net', 
To => 'to@gmail.com', 
Subject => 'Test Message', 
Data => 'This is a test', 
Type => 'text/html' 
); 

my $USERNAME = 'from@bellsouth.net'; 
my $PASSWORD = 'abc123'; 

my $smtps = Net::SMTPS->new("smtp.mail.att.net", Port => 587, doSSL => 'starttls', SSL_version=>'TLSv1'); 

$smtps->auth ($USERNAME, $PASSWORD) or die("Could not authenticate with bellsouth.\n"); 

$smtps ->mail('from@bellsouth.net'); 
$smtps->to('to@gmail.com'); 
$smtps->data(); 
$smtps->datasend($msg->as_string()); 
$smtps->dataend(); 
$smtps->quit;