Różnica czasu w sekundach

Question

W programie Perl mam zmienną zawierającą datę/czas w tym formacie:

Feb 3 12:03:20 

muszę stwierdzić, czy ta data jest więcej niż x sekund życia (na podstawie aktualnego czasu), nawet jeśli ma to miejsce po północy (np. Feb 3 23:59:00 z bieżącym czasem = Feb 4 00:00:30).

Znalezione przeze mnie informacje o dacie/godzinie są zadziwiające. W pobliżu, jak mogę powiedzieć, potrzebuję użyć Date::Calc, ale nie znajduję sekundy-delta. Dzięki :)

Answer 1

W perlu zawsze istnieje więcej niż jeden sposób na zrobienie czegoś. Oto ten, który wykorzystuje tylko moduł, który jest standardowo wyposażony w Perlu:

#! perl -w 

use strict; 
use Time::Local; 

my $d1 = "Feb 3 12:03:20"; 
my $d2 = "Feb 4 00:00:30"; 

# Your date formats don't include the year, so 
# figure out some kind of default. 
use constant Year => 2012; 


# Convert your date strings to Unix/perl style time in seconds 
# The main problems you have here are: 
# * parsing the date formats 
# * converting the month string to a number from 1 to 11 
sub convert 
{ 
    my $dstring = shift; 

    my %m = ('Jan' => 0, 'Feb' => 1, 'Mar' => 2, 'Apr' => 3, 
      'May' => 4, 'Jun' => 5, 'Jul' => 6, 'Aug' => 7, 
      'Sep' => 8, 'Oct' => 9, 'Nov' => 10, 'Dec' => 11); 

    if ($dstring =~ /(\S+)\s+(\d+)\s+(\d{2}):(\d{2}):(\d{2})/) 
    { 
     my ($month, $day, $h, $m, $s) = ($1, $2, $3, $4, $5); 
     my $mnumber = $m{$month}; # production code should handle errors here 

     timelocal($s, $m, $h, $day, $mnumber, Year - 1900); 
    } 
    else 
    { 
     die "Format not recognized: ", $dstring, "\n"; 
    } 
} 

my $t1 = convert($d1); 
my $t2 = convert($d2); 

print "Diff (seconds) = ", $t2 - $t1, "\n"; 

Aby zrobić to naprawdę produkcja gotowe, potrzebuje lepszej obsługi od roku (na przykład, co się stanie, gdy data rozpoczęcia jest w grudniu i na końcu data w styczniu?) i lepszą obsługę błędów (na przykład, co się stanie, jeśli zostanie skasowany skrót 3-znakowy miesiąca?).

Answer 2

Wydaje się, że jest wygodnie Date::Parse. Oto przykład:

use Date::Parse; 

print str2time ('Feb 3 12:03:20') . "\n"; 

A oto co wyprowadza:

$ perl test.pl 
1328288600 

który jest: Fri Feb 3 12:03:20 EST 2012

Nie jestem pewien, jak przyzwoity parsowanie jest, ale analizuje swój przykład tylko dobrze :)

Answer 3

Zakładając, że chcesz użyć Date::Calc, przekonwertuj dwie wartości na "czas" wartościami Date_to_Time, s odejmij wartości, aby uzyskać różnicę w sekundach. Ale aby to zrobić, musisz przekonwertować ciągi znaków na wartości YY MM DD hh mm ss, aby najpierw przejść do Date_to_Time.

Answer 4

W duchu TMTOWTDI można wykorzystać rdzeń Time::Piece:

#!/usr/bin/env perl 
use strict; 
use warnings; 
use Time::Piece; 
my $when = "@ARGV" or die "'Mon Day HH:MM:SS' expected\n"; 
my $year = (localtime)[5] + 1900; 
my $t = Time::Piece->strptime($year . q() . $when, "%Y %b %d %H:%M:%S"); 
print "delta seconds = ", time() - $t->strftime("%s"),"\n"; 

$ ./mydelta Lut 3 12:03:20

delta seconds = 14553 

Obecny rok zakłada i pochodzi z twój czas lokalny.

Answer 5

#!/usr/bin/perl 

$Start = time(); 
sleep 3; 
$End = time(); 
$Diff = $End - $Start; 

print "Start ".$Start."\n"; 
print "End ".$End."\n"; 
print "Diff ".$Diff."\n"; 

Jest to prosty sposób na znalezienie różnicy czasu w sekundach.