Czy `const` parametry String (gwint) bezpieczny

Question

Ten kod

procedure MyThreadTestA(const AStr: string); 

jest szybszy niż

procedure MyThreadTestB(AStr: string); 

Podczas gdy wykonywanie tej samej pracy, zarówno przekazać wskaźnik.

Jednak wersja B "poprawnie" aktualizuje wartość odniesienia o wartości AStr i tworzy kopię, jeśli ją zmieniam.
Wersja A przekazuje tylko wskaźnik, a tylko kompilator uniemożliwia zmianę AStr.

Wersja A nie jest bezpieczne jeśli robię brudnych sztuczek w asemblerze lub w inny sposób na obejście ochrony kompilatora, to jest dobrze znane, ale ...

przepuszcza AStr przez referencyjne jako const parametry wątku bezpieczne?
Co się stanie, jeśli licznik odwołań AStr w innym wątku zostanie wyzerowany, a ciąg znaków zostanie zniszczony?

Answer 1

Nie, takie sztuczki nie są bezpieczne dla wątków. Const zapobiega add-ref, więc zmiany dokonane przez inny wątek wpłyną na wartość w nieprzewidywalny sposób. Przykładowy program, spróbuj zmieniając const w definicji P:

{$apptype console} 
uses SysUtils, Classes, SyncObjs; 

type 
    TObj = class 
    public 
    S: string; 
    end; 

    TWorker = class(TThread) 
    public 
    procedure Execute; override; 
    end; 

var 
    lock: TCriticalSection; 
    obj: TObj; 

procedure P(const x: string); 
// procedure P(x: string); 
begin 
    Writeln('P(1): x = ', x); 
    Writeln('Releasing obj'); 
    lock.Release; 
    Sleep(10); // give worker a chance to run 
    Writeln('P(2): x = ', x); 
end; 

procedure TWorker.Execute; 
begin 
    // wait until TMonitor is freed up 
    Writeln('Worker started...'); 
    lock.Acquire; 
    Writeln('worker fiddling with obj.S'); 
    obj.S := 'bar'; 
    TMonitor.Exit(obj); 
end; 

procedure Go; 
begin 
    lock := TCriticalSection.Create; 
    obj := TObj.Create; 
    obj.S := 'foo'; 
    UniqueString(obj.S); 
    lock.Acquire; 
    TWorker.Create(False); 
    Sleep(10); // give worker a chance to run and block 
    P(obj.S); 
end; 

begin 
    Go; 
end. 

Ale to nie ogranicza się tylko do wątków; modyfikację podstawowej zmiennej lokalizacji ma podobne efekty:

{$apptype console} 
uses SysUtils, Classes, SyncObjs; 

type 
    TObj = class 
    public 
    S: string; 
    end; 

var 
    obj: TObj; 

procedure P(const x: string); 
begin 
    Writeln('P(1): x = ', x); 
    obj.S := 'bar'; 
    Writeln('P(2): x = ', x); 
end; 

procedure Go; 
begin 
    obj := TObj.Create; 
    obj.S := 'foo'; 
    UniqueString(obj.S); 
    P(obj.S); 
end; 

begin 
    Go; 
end. 

Answer 2

Aby dodać odpowiedź Barry'ego: To jest na pewno bezpieczny wątku, jeśli ciąg znaków, który został przekazany pochodził z lokalnym zmiennej wewnątrz zakresu rozmówców.

W takim przypadku zmienna lokalna zachowa poprawne referencje i jedynym sposobem (zakładając tylko prawidłowy kod pascalowy, brak błądzenia w ASM), aby zmienna lokalna została zmieniona, jest połączenie przychodzące.

Obejmuje to również wszystkie przypadki, w których źródło zmiennej łańcuchowej jest wynikiem wywołania funkcji (w tym dostęp do właściwości, np. TStrings.Strings []), ponieważ w tym przypadku kompilator musi przechowywać ciąg znaków w lokalnych tempach zmienna.

Problemy z bezpieczeństwem wątków mogą być spowodowane tylko bezpośrednim przekazywaniem ciągu znaków z miejsca, w którym ten ciąg może zostać zmieniony (przez ten sam lub inny wątek) przed powrotem połączenia.