Konwersja znaków "abc" do $ hash -> {a} -> {b} -> {c} w Perlu

Question

Mam dynamicznych zagnieżdżonych haszowe bibl tak:

my $hash = { 'a' => { 'b' => { 'c' => 'value' } } }; 

Chcę ustawić wartość c do "coś", pozwalając użytkownikowi wprowadzić "abc coś".

Teraz coraz wartość można zrobić tak:

my $keys = 'a.b.c'; 
my $v='something'; 
my $h = $hash; 
foreach my $k(split /\./, $keys) { 
    $h = $h->{$k}; 
} 
print $h; # "value" 

Ale jak bym ustawić wartość klucza c do $v tak że

print Dumper $hash; 

będzie odzwierciedlać zmiany ? $h nie jest ref na końcu pętli foreach, więc zmiana, która nie będzie odzwierciedlała zmiany w $hash. Jakieś wskazówki, jak rozwiązać węzły w mojej głowie?

Answer 1

coś takiego:

my $h = $hash; 
my @split_key = split /\./, $keys; 
my $last_key = pop @split_key; 
foreach my $k (@split_key) { 
    $h = $h->{$k}; 
} 
$h->{$last_key} = $v; 

Answer 2

use strictures; 
use Data::Diver qw(DiveVal); 

my ($hash, $path, $value) = (
    { 'a' => { 'b' => { 'c' => 'value' } } }, 
    'a.b.c', 
    'something', 
); 

DiveVal($hash, split /[.]/, $path) = $value; 
# { a => { b => { c => 'something' } } } 

Answer 3

wychodziły ostatni klucz do wusses! ;)

sub dive :lvalue { 
    my $r = \shift; 
    $r = \(($$r)->{$_}) for @_; 
    return $$r; 
} 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

dive($data, split /\./, $key) = $val; 

Mocniejszy (a zatem nieznacznie trudniejsze do wykorzystania) wersja zapewniona jest przez Data::Diver.

use Data::Diver qw(DiveVal); 

my $data; 
my $key = 'a.b.c'; 
my $val = 'value'; 

DiveVal($data //= {}, map \$_, split /\./, $key) = $val; 

(wykorzystanie daxim jest nieco off.)