Grupowanie XSLT Rodzeństwo

Question

Próbuję zgrupować dane rodzeństwa w pliku XML.

Dane:

<?xml version="1.0" encoding="UTF-8"?> 
<data> 
    <competition> 
     <timeline>10:00</timeline> 
     <fixture>team a v team b</fixture> 
     <fixture>team c v team d</fixture> 
     <timeline>12:00</timeline> 
     <fixture>team e v team f</fixture> 
     <timeline>16:00</timeline> 
     <fixture>team g v team h</fixture> 
     <fixture>team i v team j</fixture> 
     <fixture>team k v team l</fixture> 
    </competition> 
</data> 

Staram się produkować:

<?xml version="1.0" encoding="UTF-8"?> 
<data> 
    <competition> 
     <timeline time="10:00"> 
      <fixture>team a v team b</fixture> 
      <fixture>team c v team d</fixture> 
     </timeline> 
     <timeline time="12:00"> 
      <fixture>team e v team f</fixture> 
     </timeline> 
     <timeline time="16:00"> 
      <fixture>team g v team h</fixture> 
      <fixture>team i v team j</fixture> 
      <fixture>team k v team l</fixture> 
     </timeline> 
    </competition> 
</data> 

Używam następujące XSLT:

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 

    <xsl:template match="competition" > 

     <xsl:apply-templates select="timeline" /> 

    </xsl:template> 

    <xsl:template match="timeline"> 
     <timeline> 
      <xsl:attribute name="time" > 
       <xsl:value-of select="." /> 
      </xsl:attribute> 

      <xsl:apply-templates select="following-sibling::*" mode="copy"/> 

     </timeline> 
    </xsl:template> 

    <xsl:template match="fixture" mode="copy"> 
     <fixture> 
      <xsl:value-of select="." /> 
     </fixture> 
    </xsl:template> 

    <xsl:template match="timeline" mode="copy"> 
     <xsl:apply-templates select="following-sibling::*" mode="null" /> 
    </xsl:template> 

    <xsl:template match="*" mode="null"> 
    </xsl:template> 
</xsl:stylesheet> 

Moim problemem jest to, że nie jest zatrzymanie Oprawa przetwarzanie węzły, gdy dotrze do następnej osi czasu

Answer 1

Łatwo to zrobić, gdy prawdziwe są następujące (które zakładam, że jest):

• wszystkie <timeline> s obrębie <competition> są unikalne
• tylko w <fixture> s zaraz po dana <timeline> należą do to
• nie ma <fixture> bez elementu <timeline> zanim

Ten XSLT 1.0 Rozwiązanie:

<xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
> 

    <xsl:key name="kFixture" 
      match="fixture" 
      use="generate-id(preceding-sibling::timeline[1])" 
    /> 

    <xsl:template match="data"> 
    <xsl:copy> 
     <xsl:apply-templates select="competition" /> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="competition"> 
    <xsl:copy> 
     <xsl:apply-templates select="timeline" /> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="timeline"> 
    <xsl:copy> 
     <xsl:attribute name="time"> 
     <xsl:value-of select="." /> 
     </xsl:attribute> 
     <xsl:copy-of select="key('kFixture', generate-id())" /> 
    </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet> 

produkuje:

<data> 
    <competition> 
    <timeline time="10:00"> 
     <fixture>team a v team b</fixture> 
     <fixture>team c v team d</fixture> 
    </timeline> 
    <timeline time="12:00"> 
     <fixture>team e v team f</fixture> 
    </timeline> 
    <timeline time="16:00"> 
     <fixture>team g v team h</fixture> 
     <fixture>team i v team j</fixture> 
     <fixture>team k v team l</fixture> 
    </timeline> 
    </competition> 
</data> 

Uwaga Użycie <xsl:key> dopasować wszystkie <fixture> s należących do ("poprzedza") dana <timeline>.

Nieco krótsze, ale mniej oczywistym rozwiązaniem byłoby zmodyfikowaną tożsamość transform:

<xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
> 

    <xsl:key name="kFixture" 
      match="fixture" 
      use="generate-id(preceding-sibling::timeline[1])" 
    /> 

    <xsl:template match="* | @*"> 
    <xsl:copy> 
     <xsl:apply-templates select="*[not(self::fixture)] | @*" /> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match="timeline"> 
    <xsl:copy> 
     <xsl:attribute name="time"> 
     <xsl:value-of select="." /> 
     </xsl:attribute> 
     <xsl:copy-of select="key('kFixture', generate-id())" /> 
    </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet> 

Answer 2

spróbować czegoś takiego:

<xsl:template match="timeline"> 
    <timeline> 
      <xsl:attribute name="time" > 
        <xsl:value-of select="." /> 
      </xsl:attribute> 

      <xsl:apply-templates select="following-sibling::*[name()=fixture][1]" /> 

    </timeline> 
</xsl:template> 

<xsl:template match="fixture"> 
    <fixture> 
      <xsl:value-of select="." /> 
    </fixture> 
    <xsl:apply-templates select="following-sibling::*[name()=fixture][1]" /> 
</xsl:template> 

Answer 3

Z pomocą g Andrieu miałem aby go dostać tylko kolejny element, a nie lista następujący: roztwór

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 

    <xsl:template match="competition" > 

     <xsl:apply-templates select="timeline" /> 

    </xsl:template> 

    <xsl:template match="timeline"> 
     <timeline> 
      <xsl:attribute name="time" > 
       <xsl:value-of select="." /> 
      </xsl:attribute> 

      <xsl:apply-templates select="following-sibling::*[1]" mode="copy"/> 

     </timeline> 
    </xsl:template> 

    <xsl:template match="fixture" mode="copy"> 
     <fixture> 
      <xsl:value-of select="." /> 
     </fixture> 
     <xsl:apply-templates select="following-sibling::*[1]" mode="copy"/> 
    </xsl:template> 

    <xsl:template match="timeline" mode="copy" /> 

</xsl:stylesheet> 

Answer 4

G ANDRIEU nie działa, ponieważ niestety nie ma takich osi, jak "następne rodzeństwo".

I Alternatywnym rozwiązaniem byłoby następujące:

<xsl:template match="timeline"> 
<timeline> 
    <xsl:attribute name="time" > 
    <xsl:value-of select="." /> 
    </xsl:attribute> 

    <xsl:apply-templates select="following-sibling::*[local-name()='fixture' and position()=1]" /> 

</timeline> 
</xsl:template> 

<xsl:template match="fixture"> 
    <fixture> 
     <xsl:value-of select="." /> 
    </fixture> 
    <xsl:apply-templates select="following-sibling::*[local-name()='fixture' and position()=1]" /> 
</xsl:template> 

Answer 5

Poniższy XSLT będzie działać, nawet jeśli same terminy są rozproszone w wielu miejscach. Dla np. w xml FOLL istnieją 2 wpisy na osi czasu 10:00

<?xml version="1.0" encoding="UTF-8"?> 
<data> 
    <competition> 
     <timeline>10:00</timeline> 
     <fixture>team a v team b</fixture> 
     <fixture>team c v team d</fixture> 
     <timeline>12:00</timeline> 
     <fixture>team e v team f</fixture> 
     <timeline>16:00</timeline> 
     <fixture>team g v team h</fixture> 
     <fixture>team i v team j</fixture> 
     <fixture>team k v team l</fixture> 
     <timeline>10:00</timeline> 
     <fixture>team a v team b new</fixture> 
     <fixture>team c v team d new</fixture> 
    </competition> 
</data> 

XSLT:

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 
    <xsl:key name="TimelineDistint" match="timeline" use="."/> 

    <xsl:template match="data"> 
     <xsl:apply-templates select="competition"/> 
    </xsl:template> 

    <xsl:template match="competition"> 
     <data> 
      <competition> 
       <xsl:for-each select="timeline[generate-id() = generate-id(key('TimelineDistint', .)[1])]"> 
        <timeline> 
         <xsl:variable name="varTimeline" select="."/> 
         <xsl:attribute name="time"><xsl:value-of select="normalize-space(.)"/></xsl:attribute> 
         <xsl:for-each select="../fixture[preceding::timeline[1] = $varTimeline]"> 
          <fixture> 
           <xsl:value-of select="normalize-space(.)"/> 
          </fixture> 
         </xsl:for-each> 
        </timeline> 
       </xsl:for-each> 
      </competition> 
     </data> 
    </xsl:template> 
</xsl:stylesheet> 

wyjścia:

<?xml version="1.0" encoding="UTF-8"?> 
<data> 
    <competition> 
     <timeline time="10:00"> 
      <fixture>team a v team b</fixture> 
      <fixture>team c v team d</fixture> 
      <fixture>team a v team b new</fixture> 
      <fixture>team c v team d new</fixture> 
     </timeline> 
     <timeline time="12:00"> 
      <fixture>team e v team f</fixture> 
     </timeline> 
     <timeline time="16:00"> 
      <fixture>team g v team h</fixture> 
      <fixture>team i v team j</fixture> 
      <fixture>team k v team l</fixture> 
     </timeline> 
    </competition> 
</data> 

Answer 6

Oto moja próba. Jedno z założonych przeze mnie założeń, które upraszcza to, że elementy osi czasu o określonej wartości tekstowej są już unikalne.

<?xml version="1.0" encoding="UTF-8" ?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" encoding="UTF-8" /> 

    <xsl:template match="/data"> 
    <data> 
     <xsl:apply-templates select="competition" /> 
    </data> 
    </xsl:template> 

    <xsl:template match="competition"> 
    <xsl:for-each select="timeline"> 
     <timeline time="{text()}"> 
     <xsl:copy-of 
      select="./following-sibling::fixture[count(preceding-sibling::timeline[1] | current()) = 1]" /> 
     </timeline> 
    </xsl:for-each> 
    </xsl:template> 

</xsl:stylesheet> 

Powyższe jest edytowane w celu użycia current() zamiast zmiennej zgodnie z sugestią Tomalaka.