Profile Maven odpowiednik Gradle

Question

Staram się osiągnąć prosty scenariusz w mojej budowie wiosennego projektu: włączanie/wyłączanie zależności i pakowanie wojny lub słoika w zależności od środowiska.

Tak na przykład dla środowiska dev obejmują DevTools i pakiet JAR dla prod pakietu wojny itp

wiem, że nie jest już oparty na XML konfiguracja i mogę w zasadzie napisać if ale w moim build.gradle czy istnieje zalecany sposób osiągnięcia tego?

Czy mogę zadeklarować niektóre typowe zależności i odsyłać je w jednym pliku zamiast tworzyć wiele plików kompilacji?

Czy istnieje najlepsza praktyka zmieniająca konfigurację kompilacji na podstawie środowiska docelowego kompilacji?

Answer 1

ext { 
    devDependencies = ['org.foo:dep1:1.0', 'org.foo:dep2:1.0'] 
    prodDependencies = ['org.foo:dep3:1.0', 'org.foo:dep4:1.0'] 
    isProd = System.properties['env'] == 'prod' 
    isDev = System.properties['env'] == 'dev' 
} 

apply plugin: 'java' 

dependencies { 
    compile 'org.foo:common:1.0' 
    if (isProd) { 
     compile prodDependencies 
    } 
    if (isDev) { 
     compile devDependencies 
    } 
} 

if (isDev) tasks.withType(War).all { it.enabled = false } 

Answer 2

Moja wersja (zainspirowany Lance Java's answer):

apply plugin: 'war' 

ext { 
    devDependencies = { 
    compile 'org.foo:dep1:1.0', { 
     exclude module: 'submodule' 
    } 
    runtime 'org.foo:dep2:1.0' 
    } 

    prodDependencies = { 
    compile 'org.foo:dep1:1.1' 
    } 

    commonDependencies = { 
    compileOnly 'javax.servlet:javax.servlet-api:3.0.1' 
    } 

    env = project.hasProperty('env') ? project.env : 'dev' 
} 

dependencies project."${env}Dependencies" 
dependencies project.commonDependencies 

if (env == 'dev') { 
    war.enabled = false 
}