Jaki jest najlepszy sposób na odkrycie wszystkich zmiennych, które obecnie określa aplikacja Perl?

Question

szukam najlepszy, najprostszy sposób zrobić coś takiego:

$var1="value"; 
bunch of code..... 
**print allVariablesAndTheirValuesCurrentlyDefined;** 

Answer 1

Zmienne pakietowe? Zmienne leksykalne?

Zmienne pakietowe można przejrzeć za pomocą tabeli symboli. Spróbuj Devel::Symdump:

#!/path/to/perl 

use Devel::Symdump; 

package example; 

$var = "value"; 
@var = ("value1", "value2"); 
%var = ("key1" => "value1", "key2" => "value2"); 

my $obj = Devel::Symdump->new('example'); 

print $obj->as_string(); 

zmienne leksykalne są trochę tricker, nie znajdziesz ich w tablicy symboli. Mogą być spojrzał przez „scratchpad” należącym do bloku kodu są one zdefiniowane w Wypróbuj PadWalker.

#!/path/to/perl 

use strict; 
use warnings; 

use Data::Dumper; 
use PadWalker qw(peek_my); 

my $var = "value"; 
my @var = ("value1", "value2"); 
my %var = ("key1" => "value1", "key2" => "value2"); 

my $hash_ref = peek_my(0); 

print Dumper($hash_ref); 

Answer 2

globalna tablica symboli jest %main::, dzięki czemu można uzyskać zmienne globalne stamtąd. Jednak każdy wpis to typeglob, który może zawierać wiele wartości, np. $ X, @x,% x, itp., Więc musisz sprawdzić dla każdego typu danych. Możesz znaleźć kod, który to robi here. Komentarze na tej stronie mogą pomóc w znalezieniu innych rozwiązań dla zmiennych innych niż globalne (takich jak zmienne leksykalne zadeklarowane jako "moje").

Answer 3

Nathan's answer jest częścią historii - niestety, reszta historii jest to, że zmienne leksykalne nie są wymienione w %main:: lub gdziekolwiek indziej (przynajmniej nigdzie dostępny od Perl - to chyba można napisać kod owłosioną XS który wykopuje te informacje z wewnętrznych elementów Perla na poziomie C).

Zmienne leksykalne są zwykle używane w przypadku zmiennych "zwykłych lokalnych". Są one zadeklarowane jak:

my $x; 

Answer 4

Moduł PadWalker daje peek_my i peek_our która przyjmowała argumentu poziomu, który określa, który zakres szukać zmiennych:

The LEVEL argument is interpreted just like the argument to caller. 
So peek_my(0) returns a reference to a hash of all the my variables 
that are currently in scope; peek_my(1) returns a reference to a hash 
of all the my variables that are in scope at the point where the 
current sub was called, and so on. 

Oto przykład:

#!/usr/bin/perl 

use strict; 
use warnings; 

use PadWalker qw/peek_my/; 

my $baz = "hi"; 

foo(); 

sub foo { 
    my $foo = 5; 
    my $bar = 10; 

    print "I have access to these variables\n"; 
    my $pad = peek_my(0); 
    for my $var (keys %$pad) { 
     print "\t$var\n"; 
    } 

    print "and the caller has these variables\n"; 
    $pad = peek_my(1); 
    for my $var (keys %$pad) { 
     print "\t$var\n"; 
    } 
} 

Answer 5

Mogłoby to być coś innego niż dla celów debugowania? Jeśli nie, możesz zapoznać się z perl's debugger. Po wejściu do debuggera możesz sprawdzić wszystkie zmienne, wydając "V".