Jak przywrócić wartość domyślną z zapytania SQL

Question

Czy istnieje prosty sposób na zwrócenie pojedynczej wartości skalarnej lub wartości domyślnej, jeśli zapytanie nie zwraca żadnego wiersza?

W tej chwili mam coś takiego przykładu kodu:

IF (EXISTS (SELECT * FROM Users WHERE Id = @UserId)) 
    SELECT Name FROM Users WHERE Id = @UserId 
ELSE 
    --default value 
    SELECT 'John Doe' 

jak to zrobić w lepszy sposób bez użycia if-else?

Answer 1

Zakładając, że nazwa nie jest pustych i Id jest wyjątkowy więc może się równać co najwyżej jednym rzędzie.

SELECT 
    ISNULL(MAX(Name),'John Doe') 
FROM 
    Users 
WHERE 
    Id = @UserId 

Answer 2

Spróbuj ISNULL lub COALESCE:

SELECT ISNULL((SELECT TOP 1 Name FROM Users WHERE Id = @UserId), 'John Doe') 

Wewnętrzna select zwróci nic, jeśli użytkownik nie istnieje z tego identyfikatora, IsNull rozwiąże tę sprawę.

Answer 3

Możesz pominąć instrukcję if, korzystając z poniższej konstrukcji, ale to niekoniecznie oznacza, że ​​jest lepsza.

SELECT Name FROM Users WHERE Id = @UserId UNION ALL 
SELECT 'John Doe' WHERE NOT EXISTS (SELECT Name FROM Users WHERE Id = @UserId) 

Answer 4

Spróbuj IsNull

SELECT IsNULL(Name, 'John Doe') FROM Users WHERE Id = @UserId 

EDIT:

drop table users 
go 
create table users 
(id int,name varchar(20)) 
go 
insert into users select 1,'1' 
go 
declare @userid int 
set @userid = 1 
select isnull(username.username, 'John Doe') 
from (select @userid as userid) userid 
outer apply (SELECT name as username FROM Users WHERE Id = userid.userid) username 
--outer apply (SELECT name as username FROM Users WHERE Id = @userid) username 

Answer 5

Przypuszczam, że można używać @@ ROWCOUNT aby sprawdzić, czy zostaną zwrócone.

SELECT Name FROM Users WHERE Id = @UserId 
if(@@ROWCOUNT = 0) 
    SELECT 'John Doe' 

Możesz także użyć zmiennej, jeśli spodziewasz się jednego wiersza.

declare @name varchar(100) 
set @name = (select top 1 name from users where id = @userId) 
if(@name is null) set @name = 'John Doe' 
select @name 

Answer 6

Sugerowałbym, że najlepszym sposobem na zrobienie tego jest najpierw zadeklarowanie @name. Następnie ustaw tę wartość na podstawie identyfikatora użytkownika, a następnie, jeśli @name ma wartość null, wyświetl domyślną nazwę, inaczej wyświetl nazwę ... Ta metoda byłaby tak samo skuteczna, jak każda inna metoda, i będzie bardziej czytelna. W przypadku innych metod, każdy inny użytkownik pomyśli o dużo wiedzieć, co się dzieje, chyba że jest ładny komentarz.

declare @userid int 
set @userid = 1 
select isnull(
       (select name from users where id = @userid), 
       'John Doe' 
       ) 
go 
--My preffered would be this one.. 
declare @name varchar(20),@userid int 
set @userid = 1 
select @name = name from users where id = @userid 
select isnull(@name,'John Doe') 

Answer 7

Try this 
`SELECT IFNULL(Name,'John Doe') FROM Users WHERE Id = @UserId)`