Niestandardowe sortowanie tablicy w Perl

Question

mam perla tablicę do wykonania zadań, które wygląda następująco:

@todos = (
    "1 (A) Complete online final @evm4700 t:2010-06-02", 
    "3 Write thank-you t:2010-06-10", 
    "4 (B) Clean t:2010-05-30", 
    "5 Donate to LSF t:2010-06-02", 
    "6 (A) t:2010-05-30 Pick up dry cleaning", 
    "2 (C) Call Chris Johnson t:2010-06-01" 
); 

To jest pierwszy numer ID zadania jest. Jeśli zadanie ma ([A-Z]) obok, określa priorytet zadania. Co chcę zrobić, to rodzaj tablicy zadania w sposób, który stawia priorytetowych elementów pierwszy (i w kolejności malejącej, od A - Z):

@todos = (
    "1 (A) Complete online final @evm4700 t:2010-06-02", 
    "6 (A) t:2010-05-30 Pick up dry cleaning", 
    "4 (B) Clean t:2010-05-30", 
    "2 (C) Call Chris Johnson t:2010-06-01" 
    "3 Write thank-you t:2010-06-10", 
    "5 Donate to LSF t:2010-06-02", 
); 

Nie mogę użyć zwykłego sort() powodu tych identyfikatorów obok zadań, więc zakładam, że potrzebny jest jakiś niestandardowy podprogram sortowania. Jednak moja wiedza na temat tego, jak zrobić to skutecznie w perlu jest minimalna.

Dzięki, wszystkie.

Answer 1

Brzmi jak chcesz Schwartzian transform:

@todos = 
    map { $_->[0] } 
    sort { $a->[1] cmp $b->[1] or $a->[0] cmp $b->[0] } 
    map { [ $_, /^\d+ \(([[:alpha:]])\)/ ? $1 : "[" ] } 
    @todos; 

"[" jest postać po "Z"; nadanie tego "priorytetu" innym pozycjom niepriorytetycznym spowoduje ich sortowanie po priorytetowych pozycjach.

Alternatywnie, i być może łatwiej chwytania:

@todos = 
    map { substr $_, 1 } 
    sort 
    map { (/^\d+ \(([[:alpha:]])\)/ ? $1 : "[") . $_ } 
    @todos; 

Answer 2

Oto stałym @Sean's solution że używa swego liczbową dla identyfikatorów zadań (tym samym 10-ci zadanie idzie po 9 tak jak powinien):

my @sorted_todos = map { $_->[0] } 
    sort { $a->[1][1] cmp $b->[1][1] # A 
         || 
      $a->[1][0] <=> $b->[1][0] # 1 
    } map { [ $_, /^(\d+) \(([[:alpha:]])\)/ ? [$1, $2] : [0, "zz"]] } @todos; 

Answer 3

Oto wersja, która jest dość jednoznaczna, jak to działa:

my @sorted_todos = sort { 
    my ($right_prio) = ($b =~ /^\d+\s+\(([A-Z])\)/); 
    return -1 unless defined $right_prio; 
    my ($left_prio) = ($a =~ /^\d+\s+\(([A-Z])\)/); 
    return 1 unless defined $left_prio; 
    return $left_prio cmp $right_prio; 
} @todos; 

Answer 4

use Sort::Key 'keysort'; 

my @sorted = keysort { /^\d+\s+\(([A-Z])\)/ ? $1 : 'ZZ' } @todos; 

Answer 5

znacznie prostsze rozwiązanie:

sort {($a =~ /\((.)\)/)[0] cmp ($b =~ /\((.)\)/)[0]} @todos;