Jak zastosować szablony do każdego wybranego węzła w jednostce for?

Question

Wiem, że czegoś tutaj brakuje. W poniższej transformacji XSLT rzeczywisty wynik nie pasuje do pożądanego wyniku.

Wewnątrz for-each, chcę zastosować szablon match="track" do każdego wybranego elementu track. Jeśli zrozumiałem XSLT poprawnie, z bieżącą konfiguracją tylko węzły podrzędne każdego wybranego elementu są dopasowane do szablonów, a nie same do siebie elementy track.

Jak ustawić elementy track przez szablon zgodnie z potrzebami? Czy muszę przemyśleć całe moje podejście?

Uwaga: Transformacja jest wykonywana przy użyciu PHP. Deklaracje XML zostały pominięte dla zwięzłości.

XML Document:

<album> 
    <title>Grave Dancers Union</title> 
    <track id="shove">Somebody To Shove</track> 
    <track id="gold">Black Gold</track> 
    <track id="train">Runaway Train</track> 
    <producer>Michael Beinhorn</producer> 
</album> 

XSL Stylesheet:

<xsl:stylesheet version="1.1" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="/album"> 
     <ol> 
      <xsl:for-each select="track"> 
       <li><xsl:apply-templates/></li> 
      </xsl:for-each> 
     </ol> 
    </xsl:template> 

    <xsl:template match="track"> 
     <a href="{@id}"><xsl:apply-templates/></a> 
    </xsl:template> 
</xsl:stylesheet> 

Wynik:

<ol> 
    <li>Somebody To Shove</li> 
    <li>Black Gold</li> 
    <li>Runaway Train</li> 
</ol> 

pożądany rezultat:

<ol> 
    <li><a href="shove">Somebody To Shove</a></li> 
    <li><a href="gold">Black Gold</a></li> 
    <li><a href="train">Runaway Train</a></li> 
</ol> 

Answer 1

Zgadzam się z "ndim", że prawdopodobnie należy zrestrukturyzować swój XSLT, aby zlikwidować pętlę xsl: for-each.

Alternatywnie, można zmienić xsl: apply-templates wybierz bieżący węzeł ścieżki wewnątrz xsl: for-each

<xsl:for-each select="track"> 
    <li> 
     <xsl:apply-templates select="." /> 
    </li> 
</xsl:for-each> 

Utrzymanie xsl: for-each byłoby przynajmniej pozwalają na sortuj utwory w innej kolejności, jeśli chcesz.

Answer 2

bym zrestrukturyzować to trochę (jeśli nie trzeba sortowania podejście for-each umożliwia):

<xsl:template match="/album"> 
    <ol> 
    <xsl:apply-templates select="track"/> 
    </ol> 
</xsl:template> 

<xsl:template match="track"> 
    <li><a href="{@id}"><xsl:apply-templates/></a></li> 
<xsl:template> 

To wygląda krótsze i bardziej na miejscu , MOIM ZDANIEM.

Chyba Twój

<xsl:for-each select="track"> 
     <li><xsl:apply-templates/></li> 
    </xsl:for-each> 

spacery przez wszystkich elementów torowych z for-each, a następnie stosuje zasady domyślne dla swoich potomków. Tak więc zawartość for-each ma ten sam węzeł kontekstu, co szablon match="track", a zatem szablon match="track" nigdy nie jest zgodny.

Jeśli naprawdę chcesz używać for-each w ten sposób, trzeba będzie zmienić jeden z następujących dwóch rzeczy w swoim podejściu:

1. Dodaj atrybut name="track" do szablonu match="track", a następnie użyj <xsl:call-template/> od for-each (mój pomysł, i gorzej niż Tim C)
2. Użyj rozwiązania Tim C przy użyciu <xsl:apply-templates select="."/>. Ma to tę zaletę, że unika nazywania i utrzymywania możliwości sortowania ścieżek.