Czy istnieje standardowa funkcja Delphi do usuwania kodu HTML?

Question

Mam raport, który ma podjąć kontrolę siatki i produkcji HTML. Jedna z kolumn w siatce może wyświetlać dowolną liczbę wartości lub <Any>. Kiedy to zostanie wyprowadzone do HTML, oczywiście kończy się pusta.

Mogłabym prawdopodobnie napisać jakąś procedurę, żeby użyć StringReplace, aby zamienić ją w <Any>, aby poprawnie wyświetlić ten konkretny przypadek, ale sądzę, że prawdopodobnie jest gdzieś w RTL gdzieś już testowany i robi to dobrze. Czy ktoś wie, gdzie mogę go znaleźć?

Answer 1

Mam 99% pewności, że taka funkcja nie istnieje w RTL (od Delphi 2009). Oczywiście - napisanie takiej funkcji jest trywialne.

Aktualizacja

HTTPUtil.HTMLEscape jest to, czego szukasz:

function HTMLEscape(const Str: string): string; 

nie odważył się opublikować kod tutaj (naruszenie praw autorskich, chyba), ale rutyna jest bardzo prosty. Koduje "<", ">", "&" i ""”, aby <, >, & i ". Zastępuje ono także znaki # 92, # 160 .. # 255 na dziesiętne kody, np \.

Ten ostatni etap jest konieczne, jeśli plik jest UTF-8, a także nielogicznego, ponieważ wyższe znaków specjalnych, takich jak ∮ pozostały jako takie, podczas gdy niższe znaki specjalne takie jak krotne są kodowane.

Aktualizacja 2

W odpowiedzi na odpowiedź Stijn Sanders wykonałem prosty test wydajności.

program Project1; 

{$APPTYPE CONSOLE} 

uses 
    Windows, SysUtils; 

var 
    t1, t2, t3, t4: Int64; 
    i: Integer; 
    str: string; 
const 
    N = 100000; 


function HTMLEncode(const Data: string): string; 
var 
    i: Integer; 
begin 

    result := ''; 
    for i := 1 to length(Data) do 
    case Data[i] of 
     '<': result := result + '&lt;'; 
     '>': result := result + '&gt;'; 
     '&': result := result + '&amp;'; 
     '"': result := result + '&quot;'; 
    else 
     result := result + Data[i]; 
    end; 

end; 

function HTMLEncode2(Data: string):string; 
begin 
    Result:= 
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
     Data, 
     '&','&amp;',[rfReplaceAll]), 
     '<','&lt;',[rfReplaceAll]), 
     '>','&gt;',[rfReplaceAll]), 
     '"','&quot;',[rfReplaceAll]); 
end; 

begin 

    QueryPerformanceCounter(t1); 
    for i := 0 to N - 1 do 
    str := HTMLEncode('Testing. Is 3*4<3+4? Do you like "A & B"'); 
    QueryPerformanceCounter(t2); 

    QueryPerformanceCounter(t3); 
    for i := 0 to N - 1 do 
    str := HTMLEncode2('Testing. Is 3*4<3+4? Do you like "A & B"'); 
    QueryPerformanceCounter(t4); 

    Writeln(IntToStr(t2-t1)); 
    Writeln(IntToStr(t4-t3)); 

    Readln; 


end. 

Wyjście jest

532031 
801969 

Answer 2

I zazwyczaj wystarczy użyć tego kodu:

function HTMLEncode(Data:string):string; 
begin 
    Result:= 
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
    StringReplace(
     Data, 
     '&','&',[rfReplaceAll]), 
     '<','&lt;',[rfReplaceAll]), 
     '>','&gt;',[rfReplaceAll]), 
     '"','&quot;',[rfReplaceAll]), 
     #13#10,'<br />'#13#10,[rfReplaceAll]); 
end; 

(? Autorskich jest open source)

Answer 3

Wydaje tutaj jest mały konkurs :) Oto jeszcze jedna implementacja:

function HTMLEncode3(const Data: string): string; 
var 
    iPos, i: Integer; 

    procedure Encode(const AStr: String); 
    begin 
    Move(AStr[1], result[iPos], Length(AStr) * SizeOf(Char)); 
    Inc(iPos, Length(AStr)); 
    end; 

begin 
    SetLength(result, Length(Data) * 6); 
    iPos := 1; 
    for i := 1 to length(Data) do 
    case Data[i] of 
     '<': Encode('&lt;'); 
     '>': Encode('&gt;'); 
     '&': Encode('&amp;'); 
     '"': Encode('&quot;'); 
    else 
     result[iPos] := Data[i]; 
     Inc(iPos); 
    end; 
    SetLength(result, iPos - 1); 
end; 

Aktualizacja 1: Zaktualizowany początkowo podał nieprawidłowy kod.

Aktualizacja 2: a czasy:

HTMLEncode : 2286508597 
HTMLEncode2: 3577001647 
HTMLEncode3: 361039770 

Answer 4

Jednostka HTTPApp posiada funkcję o nazwie HtmlEncode. Ma również inne funkcje powiązane z HTML/HTTP.

Answer 5

jak o tej drodze zastąpienia znaków specjalnych:

function HtmlWeg(sS: String): String; 
var 
    ix,cc: Integer; 
    sC, sR: String; 
begin 
    result := sS; 
    ix := pos('\u00',sS); 

    while ix >0 do 
    begin 
    sc := copy(sS,ix+4,2) ; 
    cc := StrtoIntdef('$' +sC,32); 
    sR := '' + chr(cc); 
    sS := Stringreplace(sS, '\u00'+sC,sR,[rfreplaceall]) ; 
    ix := pos('\u00',sS); 
    end; 
    result := sS; 
end; 

Answer 6

Moja funkcja łączy w pętli for z minimalną realokacji napisu:

function HtmlEncode(const Value: string): string; 
var 
    i: Integer; 

begin 
    Result := Value; 
    i := 1; 

    while i <= Length(Result) do 
    begin 
    if Result[i] = '<' then 
    begin 
     Result[i] := '&'; 
     Insert('lt;', Result, i + 1); 
     Inc(i, 4); 
    end 
    else if Result[i] = '>' then 
    begin 
     Result[i] := '&'; 
     Insert('gt;', Result, i + 1); 
     Inc(i, 4); 
    end 
    else if Result[i] = '"' then 
    begin 
     Result[i] := '&'; 
     Insert('quot;', Result, i + 1); 
     Inc(i, 6); 
    end 
    else if Result[i] = '&' then 
    begin 
     Insert('amp;', Result, i + 1); 
     Inc(i, 5); 
    end 
    else 
     Inc(i); 
    end; 
end; 

Answer 7

nie wiem w której wersji go Delphi został wprowadzony, ale istnieje jednostka System.NetEncoding, która ma:

TNetEncoding.HTML.Encode 
TNetEncoding.HTML.Decode 

f unkcje. Przeczytaj artykuł here. Nie potrzebujesz już do tego zewnętrznych bibliotek.