Delphi dbgrid ciągłe przewijanie

Question

Wykonuję aplikację, która przechowuje zamówienia i drukuje faktury. Mam kilka etykiet, tedi, tmemos, buttons, źródło danych, adotable, popupmenu i dbgrid w moim formularzu.

Kiedy buduję program i przewijam w dół pasek przewijania dbgrid, przewija się po zwolnieniu przycisku myszy. Ale chcę ciągłego przewijania.

Pozdrowienia

Answer 1

To się nazywa śledzenie kciukiem. Wyprowadź nową klasę, aby zastąpić zachowanie przewijania. Przykład użycia klasy interposer:

type 
    TDBGrid = class(DBGrids.TDBGrid) 
    private 
    procedure WmVScroll(var Message: TWMVScroll); message WM_VSCROLL; 
    end; 

    TForm1 = class(TForm) 
    DBGrid1: TDBGrid; 
    .. 

implementation 

procedure TDBGrid.WmVScroll(var Message: TWMVScroll); 
begin 
    if Message.ScrollCode = SB_THUMBTRACK then 
    Message.ScrollCode := SB_THUMBPOSITION; 
    inherited; 
end; 

Można również wymienić WindowProc z kontrolą, jeśli nie chcą czerpać nową klasę. Wszystko, co musisz zrobić, to obsłużyć wiadomość WM_VSCROLL. Here jest przykładem, jak to zrobić.

Answer 2

Oto inne rozwiązanie Sertac Akyuz wymienić bez konieczności uzyskania nowej klasy z TDBGrid:

private 
    FOrgDBGridWndProc: TWndMethod; 
    procedure DBGridWndProc(var Msg: TMessage); 
    // ... 
    end; 

procedure TForm1.FormCreate(Sender: TObject); 
begin 
    FOrgDBGridWndProc:= DBGrid1.WindowProc; 
    DBGrid1.WindowProc := DBGridWndProc; 
end; 

procedure TForm1.DBGridWndProc(var Msg: TMessage); 
begin 
    if (Msg.Msg = WM_VSCROLL) and 
    (LongRec(Msg.wParam).Lo = SB_THUMBTRACK) then 
    begin 
     LongRec(Msg.wParam).Lo := SB_THUMBPOSITION; 
    end; 
    if Assigned(FOrgDBGridWndProc) then 
    FOrgDBGridWndProc(Msg); 
end;