Perl: Przekieruj STDOUT do dwóch plików

Question

Jak mogę przekierować strumień STDOUT do dwóch plików (duplikatów) w moim skrypcie Perla? Aktualnie przesyłam tylko jeden plik dziennika:

open(STDOUT, ">$out_file") or die "Can't open $out_file: $!\n"; 

Co muszę zmienić? Dzięki.

Answer 1

Można również użyć IO::Tee.

use strict; 
use warnings; 
use IO::Tee; 

open(my $fh1,">","tee1") or die $!; 
open(my $fh2,">","tee2") or die $!; 

my $tee=IO::Tee->new($fh1,$fh2); 

select $tee; #This makes $tee the default handle. 

print "Hey!\n"; #Because of the select, you don't have to do print $tee "Hey!\n" 

I tak, wyjście działa:

> cat tee1 
Hey! 
> cat tee2 
Hey! 

Answer 2

Jeśli używasz systemu uniksowego, użyj narzędzia tee.

$ perl -le 'print "Hello, world"' | tee /tmp/foo /tmp/bar 
Hello, world 

$ cat /tmp/foo /tmp/bar 
Hello, world 
Hello, world

Aby skonfigurować tę powielania z poziomu programu, założyć rurkę z STDOUT do zewnętrznego tee procesu. Przekazywanie "|-" do open ułatwia to zadanie.

#! /usr/bin/env perl 

use strict; 
use warnings; 

my @copies = qw(/tmp/foo /tmp/bar); 

open STDOUT, "|-", "tee", @copies or die "$0: tee failed: $!"; 

print "Hello, world!\n"; 

close STDOUT or warn "$0: close: $!"; 

Demo:

$ ./stdout-copies-demo 
Hello, world! 

$ cat /tmp/foo /tmp/bar 
Hello, world! 
Hello, world!

Answer 3

File::Tee zapewnia funkcjonalność, której potrzebujesz.

use File::Tee qw(tee); 
tee(STDOUT, '>', 'stdout.txt'); 

Answer 4

Użyj warstwy PerlIO tee.

use PerlIO::Util; 
*STDOUT->push_layer(tee => "/tmp/bar"); 
print "data\n"; 

$ perl tee_script.pl > /tmp/foo 
$ cat /tmp/foo 
data 
$ cat /tmp/bar 
data