Jak mogę zmienić kolor linii stanu vim?

Question

Próbuję zmienić kolor linii statusu vima, edytując mój .vimrc.

Używając polecenia au, próbowałem zmienić kolor linii statusu podczas wchodzenia do lub wychodzenia z trybu wstawiania; Za pomocą tego polecenia nic się nie dzieje:

hi StatusLine guibg=whatevercolourIwant

Zmieniając kolor linii statusu bezpośrednio, bez żadnej komendy au, tło pozostaje taka sama.

Czy istnieje powód, wykonując

:hi StatusLine guibg=red,

na przykład tło na pasku stanu nadal zielonkawe?

Answer 1

jeśli używasz Vima w terminalu, spróbuj:

hi StatusLine ctermbg=whatever ctermfg=whatever 

guibg guifg są dla GUI.

nadzieję, że to pomaga.

Answer 2

Używam tego na moim pasku stanu, który zmienia kolor w zależności od linii, co jestem w tryb między innymi ciekawostki:

function! InsertStatuslineColor(mode) 
    if a:mode == 'i' 
    hi statusline guibg=Cyan ctermfg=6 guifg=Black ctermbg=0 
    elseif a:mode == 'r' 
    hi statusline guibg=Purple ctermfg=5 guifg=Black ctermbg=0 
    else 
    hi statusline guibg=DarkRed ctermfg=1 guifg=Black ctermbg=0 
    endif 
endfunction 

au InsertEnter * call InsertStatuslineColor(v:insertmode) 
au InsertLeave * hi statusline guibg=DarkGrey ctermfg=8 guifg=White ctermbg=15 

" default the statusline to green when entering Vim 
hi statusline guibg=DarkGrey ctermfg=8 guifg=White ctermbg=15 

" Formats the statusline 
set statusline=%f       " file name 
set statusline+=[%{strlen(&fenc)?&fenc:'none'}, "file encoding 
set statusline+=%{&ff}] "file format 
set statusline+=%y  "filetype 
set statusline+=%h  "help file flag 
set statusline+=%m  "modified flag 
set statusline+=%r  "read only flag 

" Puts in the current git status 
    if count(g:pathogen_disabled, 'Fugitive') < 1 
     set statusline+=%{fugitive#statusline()} 
    endif 

" Puts in syntastic warnings 
    if count(g:pathogen_disabled, 'Syntastic') < 1 
     set statusline+=%#warningmsg# 
     set statusline+=%{SyntasticStatuslineFlag()} 
     set statusline+=%* 
    endif 

set statusline+=\ %=      " align left 
set statusline+=Line:%l/%L[%p%%]   " line X of Y [percent of file] 
set statusline+=\ Col:%c     " current column 
set statusline+=\ Buf:%n     " Buffer number 
set statusline+=\ [%b][0x%B]\    " ASCII and byte code under cursor 

Answer 3

To naprawdę niesamowite kawałek kodu !!

Zmodyfikowałem go, aby odpowiadał moim potrzebom. Dodałem trochę sformułowania do mojego stanu bufora:

[zapisane] lub [zmodyfikowane].

Ustawiam kolor paska stanu na podstawie zdarzenia zmiany bufora. DarkSlateGray dla niezmienionej/normalnej. OrangeRed4, jeśli zostały wykonane jakieś modyfikacje.

Oto mój zmodyfikowany kod:

" Some funky status bar code its seems 
" https://stackoverflow.com/questions/9065941/how-can-i-change-vim-status-line-colour 
set laststatus=2   " set the bottom status bar 

function! ModifiedColor() 
    if &mod == 1 
     hi statusline guibg=White ctermfg=8 guifg=OrangeRed4 ctermbg=15 
    else 
     hi statusline guibg=White ctermfg=8 guifg=DarkSlateGray ctermbg=15 
    endif 
endfunction 

au InsertLeave,InsertEnter,BufWritePost * call ModifiedColor() 
" default the statusline when entering Vim 
hi statusline guibg=White ctermfg=8 guifg=DarkSlateGray ctermbg=15 

" Formats the statusline 
set statusline=%f       " file name 
set statusline+=[%{strlen(&fenc)?&fenc:'none'}, "file encoding 
set statusline+=%{&ff}] "file format 
set statusline+=%y  "filetype 
set statusline+=%h  "help file flag 
set statusline+=[%{getbufvar(bufnr('%'),'&mod')?'modified':'saved'}]  
"modified flag 

set statusline+=%r  "read only flag 

set statusline+=\ %=      " align left 
set statusline+=Line:%l/%L[%p%%]   " line X of Y [percent of file] 
set statusline+=\ Col:%c     " current column 
set statusline+=\ Buf:%n     " Buffer number 
set statusline+=\ [%b][0x%B]\    " ASCII and byte code under cursor