QML: Nawigacja między stronami qml od percepcji projektu

Question

Musimy opracować projekt QtQuick, w którym mamy około 100 ekranów.

Próbowałem wykonać projekt demonstracyjny dla nawigacji, który ma trzy ekrany po kliknięciu przycisku. Użyłem pojęć "państwa" w nawigacji między stronami. Początkowo próbowałem tego samego używając "Loader", ale program ładujący nie był w stanie zachować poprzedniego stanu strony, był to ponowne ładowanie całej strony podczas nawigacji.

Poniżej znajduje się fragment kodu z main.qml

// import QtQuick 1.0 // to target S60 5th Edition or Maemo 5 
import QtQuick 1.1 

Rectangle { 
    id:main_rectangle 
    width: 360 
    height: 640 

    Page1{ 
     id:page1 
    } 

    Page2{ 
     id:page2 
    } 

    Page3{ 
     id:page3 
    } 

    states: [ 
     State { 

      name: "page2" 

      PropertyChanges { target: page3; visible:false; } 
      PropertyChanges { target: page1; visible:false; } 
      PropertyChanges { target: page2; visible:true; } 
     }, 
     State { 
      name: "page1" 
      PropertyChanges { target: page3; visible:false; } 
      PropertyChanges { target: page2; visible:false; } 
      PropertyChanges { target: page1; visible:true; } 
     }, 

     State { 
      name: "page3" 
      PropertyChanges { target: page1; visible:false; } 
      PropertyChanges { target: page2; visible:false; } 
      PropertyChanges { target: page3; visible:true; } 
     } 

    ] 

} 

To działa dobrze z małym PKOl z trzech ekranów, ale nie jest to możliwe, aby zdefiniować stany na 100 ekranach.

Od strony aspektu konstrukcyjnego doszliśmy do tego, aby stworzyć kontroler C++, który kontroluje stany, widoczność różnych stron.

Potrzebujesz sugestii, jak wdrożyć logikę "państwa" w C++.

Answer 1

Proponuję użyć StackView z Qt Quick Components. Here jest jego dokumentacją.

Answer 2

Oto najprostsze rozwiązanie w prostym QML, przy użyciu konfigurowalnej listy stron (jak model) + elementów typu Repeater + Loader, aby nie ładować wszystkiego podczas uruchamiania (leniwej instancji) i nie niszcz strony po jej ukryciu (aby nie przeładować, jeśli wrócimy):

import QtQuick 1.1 

Rectangle { 
    id: main_rectangle; 
    width: 360; 
    height: 640; 

    // Put the name of the QML files containing your pages (without the '.qml') 
    property variant pagesList : [ 
     "Page1", 
     "Page2", 
     "Page3", 
     "Page4", 
     "Page5" 
    ]; 

    // Set this property to another file name to change page 
    property string currentPage : "Page1"; 

    Repeater { 
     model: pagesList; 
     delegate: Loader { 
      active: false; 
      asynchronous: true; 
      anchors.fill: parent; 
      visible: (currentPage === modelData); 
      source: "%1.qml".arg(modelData) 
      onVisibleChanged:  { loadIfNotLoaded(); } 
      Component.onCompleted: { loadIfNotLoaded(); } 

      function loadIfNotLoaded() { 
       // to load the file at first show 
       if (visible && !active) { 
        active = true; 
       } 
      } 
     } 
    } 
} 

Mam nadzieję, że pomoże!