SQL Server: wyjście Filtr sp_who2

Question

Pod SQL Server, to istnieje prosty sposób filtrować wyjście sp_who2? Powiedzmy, że chciałem po prostu pokazać wiersze dla pewnej bazy danych, na przykład.

Answer 1

Można spróbować czegoś podobnego

DECLARE @Table TABLE(
     SPID INT, 
     Status VARCHAR(MAX), 
     LOGIN VARCHAR(MAX), 
     HostName VARCHAR(MAX), 
     BlkBy VARCHAR(MAX), 
     DBName VARCHAR(MAX), 
     Command VARCHAR(MAX), 
     CPUTime INT, 
     DiskIO INT, 
     LastBatch VARCHAR(MAX), 
     ProgramName VARCHAR(MAX), 
     SPID_1 INT, 
     REQUESTID INT 
) 

INSERT INTO @Table EXEC sp_who2 

SELECT * 
FROM @Table 
WHERE .... 

i filtr na to, czego potrzebują.

Answer 2

Jednym ze sposobów jest utworzenie tabeli temp:

CREATE TABLE #sp_who2 
(
    SPID INT, 
    Status VARCHAR(1000) NULL, 
    Login SYSNAME NULL, 
    HostName SYSNAME NULL, 
    BlkBy SYSNAME NULL, 
    DBName SYSNAME NULL, 
    Command VARCHAR(1000) NULL, 
    CPUTime INT NULL, 
    DiskIO INT NULL, 
    LastBatch VARCHAR(1000) NULL, 
    ProgramName VARCHAR(1000) NULL, 
    SPID2 INT 
) 
GO 

INSERT INTO #sp_who2 
EXEC sp_who2 
GO 

SELECT * 
FROM #sp_who2 
WHERE Login = 'bla' 
GO 

DROP TABLE #sp_who2 
GO 

Answer 3

Tak, poprzez przechwytywanie wyjście sp_who2 na stole, a następnie wybierając z tabeli, ale to byłby zły sposób to zrobić. Po pierwsze, ponieważ sp_who2, pomimo swojej popularności, jest procedurą nieudokumentowaną i nie powinieneś polegać na nieudokumentowanych procedurach. Po drugie, ponieważ wszystkie sp_who2 może zrobić, i wiele więcej, można uzyskać z sys.dm_exec_requests i innych DMV, a show mogą być filtrowane, uporządkowane, połączone i wszystkie inne gadżety, które pochodzą z queriable zestawów wierszy.

Answer 4

Jest procedury przechowywane tam sporo użytkownik dobre sp_who3 - Jestem pewna, że ​​Adam Machanic zrobił naprawdę dobry, AFAIK.

Adam nazywa Kto jest aktywny: http://sqlblog.com/blogs/adam_machanic/archive/tags/Scripts/default.aspx

Answer 5

podstawie http://sqlserver2005.databases.aspfaq.com/how-do-i-mimic-sp-who2.html

Stworzyłem następujący skrypt,
który rozwiązuje znalezienie aktywne połączenia do dowolnego datbase użyciu DMV to działa w SQL 2005, 2008 i 2008R2

Poniższy skrypt korzysta sys.dm_exec_sessions, sys.dm_exec_requests, sys.dm_exec_connections, sys.dm_tran_locks

Declare @dbName varchar(1000) 
set @dbName='abc' 

;WITH DBConn(SPID,[Status],[Login],HostName,DBName,Command,LastBatch,ProgramName) 
As 
(
SELECT 
    SPID = s.session_id, 
    Status = UPPER(COALESCE 
     (
      r.status, 
      ot.task_state, 
      s.status, 
     '')), 
    [Login] = s.login_name, 
    HostName = COALESCE 
     (
      s.[host_name], 
      ' .' 
     ), 
    DBName = COALESCE 
     (
      DB_NAME(COALESCE 
      (
       r.database_id, 
       t.database_id 
      )), 
      '' 
     ), 
    Command = COALESCE 
     (
      r.Command, 
      r.wait_type, 
      wt.wait_type, 
      r.last_wait_type, 
      '' 
     ), 
    LastBatch = COALESCE 
     (
      r.start_time, 
      s.last_request_start_time 
     ), 
    ProgramName = COALESCE 
     (
      s.program_name, 
      '' 
     ) 
FROM 
    sys.dm_exec_sessions s 
LEFT OUTER JOIN 
    sys.dm_exec_requests r 
ON 
    s.session_id = r.session_id 
LEFT OUTER JOIN 
    sys.dm_exec_connections c 
ON 
    s.session_id = c.session_id 
LEFT OUTER JOIN 
(
    SELECT 
     request_session_id, 
     database_id = MAX(resource_database_id) 
    FROM 
     sys.dm_tran_locks 
    GROUP BY 
     request_session_id 
) t 
ON 
    s.session_id = t.request_session_id 
LEFT OUTER JOIN 
    sys.dm_os_waiting_tasks wt 
ON 
    s.session_id = wt.session_id 
LEFT OUTER JOIN 
    sys.dm_os_tasks ot 
ON 
    s.session_id = ot.session_id 
LEFT OUTER JOIN 
(
    SELECT 
     ot.session_id, 
     CPU_Time = MAX(usermode_time) 
    FROM 
     sys.dm_os_tasks ot 
    INNER JOIN 
     sys.dm_os_workers ow 
    ON 
     ot.worker_address = ow.worker_address 
    INNER JOIN 
     sys.dm_os_threads oth 
    ON 
     ow.thread_address = oth.thread_address 
    GROUP BY 
     ot.session_id 
) tt 
ON 
    s.session_id = tt.session_id 
WHERE 
    COALESCE 
    (
     r.command, 
     r.wait_type, 
     wt.wait_type, 
     r.last_wait_type, 
     'a' 
    ) >= COALESCE 
    (
     '', 
     'a' 
    ) 
) 

Select * from DBConn 
where DBName like '%'+@dbName+'%' 

Answer 6

Lekka poprawa do odpowiedzi Astandera. Chciałbym umieścić moje kryteria na górze i ułatwić ponowne dnia na dzień:

DECLARE @Spid INT, @Status VARCHAR(MAX), @Login VARCHAR(MAX), @HostName VARCHAR(MAX), @BlkBy VARCHAR(MAX), @DBName VARCHAR(MAX), @Command VARCHAR(MAX), @CPUTime INT, @DiskIO INT, @LastBatch VARCHAR(MAX), @ProgramName VARCHAR(MAX), @SPID_1 INT, @REQUESTID INT 

    --SET @SPID = 10 
    --SET @Status = 'BACKGROUND' 
    --SET @LOGIN = 'sa' 
    --SET @HostName = 'MSSQL-1' 
    --SET @BlkBy = 0 
    --SET @DBName = 'master' 
    --SET @Command = 'SELECT INTO' 
    --SET @CPUTime = 1000 
    --SET @DiskIO = 1000 
    --SET @LastBatch = '10/24 10:00:00' 
    --SET @ProgramName = 'Microsoft SQL Server Management Studio - Query' 
    --SET @SPID_1 = 10 
    --SET @REQUESTID = 0 

    SET NOCOUNT ON 
    DECLARE @Table TABLE(
      SPID INT, 
      Status VARCHAR(MAX), 
      LOGIN VARCHAR(MAX), 
      HostName VARCHAR(MAX), 
      BlkBy VARCHAR(MAX), 
      DBName VARCHAR(MAX), 
      Command VARCHAR(MAX), 
      CPUTime INT, 
      DiskIO INT, 
      LastBatch VARCHAR(MAX), 
      ProgramName VARCHAR(MAX), 
      SPID_1 INT, 
      REQUESTID INT 
    ) 
    INSERT INTO @Table EXEC sp_who2 
    SET NOCOUNT OFF 
    SELECT * 
    FROM @Table 
    WHERE 
    (@Spid IS NULL OR SPID = @Spid) 
    AND (@Status IS NULL OR Status = @Status) 
    AND (@Login IS NULL OR Login = @Login) 
    AND (@HostName IS NULL OR HostName = @HostName) 
    AND (@BlkBy IS NULL OR BlkBy = @BlkBy) 
    AND (@DBName IS NULL OR DBName = @DBName) 
    AND (@Command IS NULL OR Command = @Command) 
    AND (@CPUTime IS NULL OR CPUTime >= @CPUTime) 
    AND (@DiskIO IS NULL OR DiskIO >= @DiskIO) 
    AND (@LastBatch IS NULL OR LastBatch >= @LastBatch) 
    AND (@ProgramName IS NULL OR ProgramName = @ProgramName) 
    AND (@SPID_1 IS NULL OR SPID_1 = @SPID_1) 
    AND (@REQUESTID IS NULL OR REQUESTID = @REQUESTID) 

Answer 7

bardzo prosty sposób to zrobić jest do utworzenia połączenia ODBC w programie Excel i uruchomić SP_WHO2 stamtąd.

można odświeżyć w dowolnym momencie, a ponieważ jest to EXCEL wszystko łatwo można manipulować!

Answer 8

Można save the results into a temp table, ale byłoby jeszcze lepiej, aby przejść bezpośrednio do źródła na master.dbo.sysprocesses

mam zbudowany to wyjście prawie dokładnie to samo, co sp_who2 generuje, oprócz tego, że można łatwo dodać ORDER BY i WHERE Klauzule, aby uzyskać znaczące wyniki.

SELECT spid, 
     sp.[status], 
     loginame [Login], 
     hostname, 
     blocked BlkBy, 
     sd.name DBName, 
     cmd Command, 
     cpu CPUTime, 
     physical_io DiskIO, 
     last_batch LastBatch, 
     [program_name] ProgramName 
FROM master.dbo.sysprocesses sp 
JOIN master.dbo.sysdatabases sd ON sp.dbid = sd.dbid 
ORDER BY spid 

Answer 9

podobne do KyleMit odpowiedź, jego można wybrać bezpośrednio z tabel używanych przez SP_WHO2, choć myślę, że to wystarczy dbo.sysprocesses tabeli.

Jeśli ktoś otworzyć SP, można go zrozumieć, co robi. To jest mój najlepszy wybierz mieć podobną moc jak SP_WHO2

select convert(char(5),sp.spid) as SPID 
     , CASE lower(sp.status) 
       When 'sleeping' Then lower(sp.status) 
       Else upper(sp.status) 
       END as Status 
     , convert(sysname, rtrim(sp.loginame)) as LOGIN 
     , CASE sp.hostname 
       When Null Then ' .' 
       When ' ' Then ' .' 
       Else rtrim(sp.hostname) 
       END as HostName 
     , CASE isnull(convert(char(5),sp.blocked),'0') 
       When '0' Then ' .' 
       Else isnull(convert(char(5),sp.blocked),'0') 
       END as BlkBy 
     , case when sp.dbid = 0 then null when sp.dbid <> 0 then db_name(sp.dbid) end as DBName 
     , sp.cmd as Command 
     , sp.cpu as CPUTime 
     , sp.physical_io as DiskIO 
     , sp.last_batch as LastBatch 
     , sp.program_name as ProgramName 
     from master.dbo.sysprocesses sp (nolock) 
    ; 

Ponad to zaznaczenie, można zaznaczyć pola trzeba i mieć żądanej kolejności.

Answer 10

Jest to rozwiązanie dla Ciebie: http://blogs.technet.com/b/wardpond/archive/2005/08/01/the-openrowset-trick-accessing-stored-procedure-output-in-a-select-statement.aspx

select * from openrowset ('SQLOLEDB', '192.168.x.x\DATA'; 'user'; 'password', 'sp_who') 

Answer 11

Rozszerzenie pierwszej i najlepszej odpowiedzi ... Ja stworzyłem procedurę przechowywaną w bazie danych master, które można następnie przekazać parametry do takich .. jak nazwa bazy danych:

USE master 
GO 

CREATE PROCEDURE sp_who_db 
(
    @sDBName varchar(200) = null, 
    @sStatus varchar(200) = null, 
    @sCommand varchar(200) = null, 
    @nCPUTime int   = null 
) 
AS 
DECLARE @Table TABLE 
(
    SPID INT, 
    Status VARCHAR(MAX), 
    LOGIN VARCHAR(MAX), 
    HostName VARCHAR(MAX), 
    BlkBy VARCHAR(MAX), 
    DBName VARCHAR(MAX), 
    Command VARCHAR(MAX), 
    CPUTime INT, 
    DiskIO INT, 
    LastBatch VARCHAR(MAX), 
    ProgramName VARCHAR(MAX), 
    SPID_1 INT, 
    REQUESTID INT 
) 

INSERT INTO @Table EXEC sp_who2 

SELECT * 
    FROM @Table 
    WHERE (@sDBName IS NULL OR DBName = @sDBName) 
    AND  (@sStatus IS NULL OR Status = @sStatus) 
    AND  (@sCommand IS NULL OR Command = @sCommand) 
    AND  (@nCPUTime IS NULL OR CPUTime > @nCPUTime) 
GO 

może przedłużyć go dodać zamówienie parametru lub nawet paramatmer kill tak zabija wszystkie połączenia do konkretnego danych