Jak zmienić nazwę otwartego pliku w Emacs?

Question

Czy istnieje sposób na zmianę nazwy otwartego pliku w Emacs? Podczas oglądania? Coś takiego jak save-as, ale oryginał powinien odejść.

Answer 1

Wypróbuj tę funkcję od Steve Yegge's .emacs:

 
;; source: http://steve.yegge.googlepages.com/my-dot-emacs-file 
(defun rename-file-and-buffer (new-name) 
    "Renames both current buffer and file it's visiting to NEW-NAME." 
    (interactive "sNew name: ") 
    (let ((name (buffer-name)) 
     (filename (buffer-file-name))) 
    (if (not filename) 
     (message "Buffer '%s' is not visiting a file!" name) 
     (if (get-buffer new-name) 
      (message "A buffer named '%s' already exists!" new-name) 
     (progn 
      (rename-file filename new-name 1) 
      (rename-buffer new-name) 
      (set-visited-file-name new-name) 
      (set-buffer-modified-p nil)))))) 

Spójrz na tej stronie, nie ma innego bardzo przydatna funkcja powiązany tam, zwany "move-buffer-file".

Answer 2

Tak, w trybie dired można:

• C-x C-j (dired-jump do nazwy bieżącego pliku, w DIRED)
• R aby zmienić nazwę pliku (lub dired-do-rename).
• C-x k RET wrócić do bufora pliku (przemianowany)

zmiany nazwy jest równoważne powłoce mv, ale również aktualizować wszystkie otwarte bufory.

Answer 3

Tylko dla kompletności, ponieważ niektórzy mogą odwiedzać tę stronę, myśląc, że dostaną odpowiedź na funkcję "zapisz jako" Emacsa, to C-x C-w dla otwartego pliku.

Answer 4

Oto bardziej solidna wersja dostosowana z Stevey.

;; Originally from stevey, adapted to support moving to a new directory. 
(defun rename-file-and-buffer (new-name) 
    "Renames both current buffer and file it's visiting to NEW-NAME." 
    (interactive 
    (progn 
    (if (not (buffer-file-name)) 
     (error "Buffer '%s' is not visiting a file!" (buffer-name))) 
    ;; Disable ido auto merge since it too frequently jumps back to the original 
    ;; file name if you pause while typing. Reenable with C-z C-z in the prompt. 
    (let ((ido-auto-merge-work-directories-length -1)) 
     (list (read-file-name (format "Rename %s to: " (file-name-nondirectory 
                 (buffer-file-name)))))))) 
    (if (equal new-name "") 
     (error "Aborted rename")) 
    (setq new-name (if (file-directory-p new-name) 
        (expand-file-name (file-name-nondirectory 
             (buffer-file-name)) 
             new-name) 
        (expand-file-name new-name))) 
    ;; Only rename if the file was saved before. Update the 
    ;; buffer name and visited file in all cases. 
    (if (file-exists-p (buffer-file-name)) 
     (rename-file (buffer-file-name) new-name 1)) 
    (let ((was-modified (buffer-modified-p))) 
    ;; This also renames the buffer, and works with uniquify 
    (set-visited-file-name new-name) 
    (if was-modified 
     (save-buffer) 
     ;; Clear buffer-modified flag caused by set-visited-file-name 
     (set-buffer-modified-p nil))) 

    (setq default-directory (file-name-directory new-name)) 

    (message "Renamed to %s." new-name)) 

Answer 5

Można to osiągnąć, kopiując. shift + c do pliku, a emacs poprosi cię o podanie nazwy ścieżki zawierającej nazwę pliku, więc podaj tylko nową nazwę i wpisz ... oczywiście, musisz usunąć poprzednią.

Answer 6

Oto kolejna wersja, że ​​to całkiem solidna i VC świadomy:

(defun rename-file-and-buffer() 
    "Rename the current buffer and file it is visiting." 
    (interactive) 
    (let ((filename (buffer-file-name))) 
    (if (not (and filename (file-exists-p filename))) 
     (message "Buffer is not visiting a file!") 
     (let ((new-name (read-file-name "New name: " filename))) 
     (cond 
     ((vc-backend filename) (vc-rename-file filename new-name)) 
     (t 
      (rename-file filename new-name t) 
      (set-visited-file-name new-name t t))))))) 

Możesz przeczytać więcej na ten temat here.

Answer 7

Moim ulubionym jest jednym z Magnars (od emacs rocks screencasts sławy.)

przeciwieństwie do innych alternatyw, nie trzeba wpisywać nazwy się od zera - dostaniesz obecna nazwa zmodyfikować.

(defun rename-current-buffer-file() 
    "Renames current buffer and file it is visiting." 
    (interactive) 
    (let* ((name (buffer-name)) 
     (filename (buffer-file-name)) 
     (basename (file-name-nondirectory filename))) 
    (if (not (and filename (file-exists-p filename))) 
     (error "Buffer '%s' is not visiting a file!" name) 
     (let ((new-name (read-file-name "New name: " (file-name-directory filename) basename nil basename))) 
     (if (get-buffer new-name) 
      (error "A buffer named '%s' already exists!" new-name) 
      (rename-file filename new-name 1) 
      (rename-buffer new-name) 
      (set-visited-file-name new-name) 
      (set-buffer-modified-p nil) 
      (message "File '%s' successfully renamed to '%s'" 
        name (file-name-nondirectory new-name))))))) 

Podziękowania dla Jamesa Yang za poprawną wersję.

Answer 8

na podstawie wersji magnars, I zmodyfikowane jak poniżej, stała się częścią nazwy pliku INIT:

(defun rename-current-buffer-file() 
    "Renames current buffer and file it is visiting." 
    (interactive) 
    (let* ((name (buffer-name)) 
     (filename (buffer-file-name)) 
     (basename (file-name-nondirectory filename))) 
    (if (not (and filename (file-exists-p filename))) 
     (error "Buffer '%s' is not visiting a file!" name) 
     (let ((new-name (read-file-name "New name: " (file-name-directory filename) basename nil basename))) 
     (if (get-buffer new-name) 
      (error "A buffer named '%s' already exists!" new-name) 
      (rename-file filename new-name 1) 
      (rename-buffer new-name) 
      (set-visited-file-name new-name) 
      (set-buffer-modified-p nil) 
      (message "File '%s' successfully renamed to '%s'" 
        name (file-name-nondirectory new-name))))))) 

Answer 9

istnieje sposób bardzo prosty, po naciśnięciu polecenia Mx i od rodzaju vc-rename- plik, po tym wystarczy wybrać bieżący plik w katalogu, a następnie wybrać nową nazwę. Buff, który ma zmieniony plik, zostanie odświeżony.

Źródło:https://www.gnu.org/software/emacs/manual/html_node/emacs/VC-Delete_002fRename.html