Jak utworzyć wrażliwy na przypadek TEqualityComparer dla TDictionary?

Question

mam przypadku użycia TDictionary:

var D: TDictionary<string, integer>; 
begin 
    D := TDictionary<string, integer>.Create(TCustomEqualityComparer.Create()); 
    try 
    D.Add('One', 1); 
    D.Add('Two', 2); 
    D.Add('Three', 3); 

    showmessage(inttostr(D.Items['One'])); 
    showmessage(inttostr(D.Items['TWO'])); 
    finally 
    D.Free; 
    end; 
end; 

klasy TCustomEqualityComparer jest kopiowany z Generics Defaults TEqualityComparer (Delphi) z drobnych modyfikacji w sposobie GetHashCode:

TCustomEqualityComparer = class(TEqualityComparer<string>) 
public 
    function Equals(const Left, Right: string): Boolean; override; 
    function GetHashCode(const Value: string): Integer; override; 
end; 

function TCustomEqualityComparer.Equals(const Left, Right: string): Boolean; 
begin 
    Result := SameText(Left, Right); 
end; 

function TCustomEqualityComparer.GetHashCode(const Value: string): Integer; 
begin 
    Result := BobJenkinsHash(Value[1], Length(Value) * SizeOf(Value[1]), 0); 
end; 

I oczekiwać TCustomEqualityComparer stanie przeprowadzić dopasowanie wielkości liter dla kluczowe wartości. Na przykład:

D.Items['TWO'] 

Jednak otrzymałem wyjątek "Nie znaleziono przedmiotu". Używam Delphi 2010 wersja 14.0.3513.24210.

Czy ktoś wie, co jest nie tak z moim kodem?

Answer 1

Dzięki. Zmieniłem TCustomEqualityComparer.GetHashCode i działa jak powiedział:

function TCustomEqualityComparer.Equals(const Left, Right: string): Boolean; 
begin 
    Result := SameText(Left, Right); 
end; 

function TCustomEqualityComparer.GetHashCode(const Value: string): Integer; 
var s: string; 
begin 
    s := UpperCase(Value); 
    Result := BobJenkinsHash(s[1], Length(s) * SizeOf(s[1]), 0); 
end; 

Answer 2

HashCode musi być taki sam dla wszystkich wartości, które zwracają Equals = true! Spróbuj wprowadzić dużą liczbę wartości w kodzie GetHashCode przed wysłaniem jej do funkcji HashFunction.

Answer 3

uses System.Generics.Collections, System.Generics.Defaults; 

var 
    D: TDictionary<string, Integer>; 
begin 
    D := TDictionary<string, Integer>.Create(TIStringComparer.Ordinal); // ‹- this is the trick 
    try 
    D.Add('One', 1); 
    . 
    . 
    finally 
    D.Free; 
    end; 
end;