Jak mogę przekonwertować z generic na Variant w Delphi

Question

Mam klasę generyczną Delphi, która udostępnia funkcję z argumentem typu ogólnego. Wewnątrz tej funkcji, muszę przekazać instancję typu ogólnego do innego obiektu oczekującego typu Wariant. Podobny do tego:

type 
    IMyInterface = interface 
    DoStuff(Value: Variant); 
    end;  

    TMyClass<T> = class 
    FMyIntf: IMyInterface 
    procedure DoStuff(SomeValue: T); 
    end; 

[...] 

procedure MyClass<T>.DoStuff(SomeValue: T); 
begin 
    FMyIntf.DoStuff((*convert SomeValue to Variant here*)); 
end; 

Próbowałem za pomocą Rtti.TValue.From (SomeValue) .AsVariant. To działało dla typów integralnych, ale wybuchło dla Booleans. Nie do końca rozumiem, dlaczego, ponieważ normalnie mógłbym przypisać wartość logiczną do wariantu ...

Czy istnieje lepszy sposób na dokonanie tej konwersji? Potrzebuję go tylko do pracy z prostymi wbudowanymi typami (z wyłączeniem wyliczeń i rekordów).

Answer 1

Myślę, że nie ma bezpośredniej metody konwersji rodzaju generycznego na wariant, ponieważ wariant nie może zawierać wszystkich możliwych typów. Musisz napisać swoją konkretną procedurę konwersji. Np .:

interface 
//... 
type 
    TDemo = class 
    public 
    class function GetAsVariant<T>(const AValue: T): Variant; 
    end; 
//... 
implementation 
uses 
    Rtti, 
    TypInfo; 
//... 

{ TDemo} 

class function TDemo.GetAsVariant<T>(const AValue: T): Variant; 
var 
    val: TValue; 
    bRes: Boolean; 
begin 
    val := TValue.From<T>(AValue); 
    case val.Kind of 
    tkInteger: Result := val.AsInteger; 
    tkInt64: Result := val.AsInt64; 
    tkEnumeration: 
    begin 
     if val.TryAsType<Boolean>(bRes) then 
     Result := bRes 
     else 
     Result := val.AsOrdinal; 
    end; 
    tkFloat: Result := val.AsExtended; 
    tkString, tkChar, tkWChar, tkLString, tkWString, tkUString: 
     Result := val.AsString; 
    tkVariant: Result := val.AsVariant 
    else 
    begin 
     raise Exception.Create('Unsupported type'); 
    end; 
    end; 
end; 

Ponieważ TValue.AsVariant obsługuje większość konwersji typu wewnętrznie, funkcja ta może być uproszczona. będę obsługiwać wyliczeń w przypadku mogłyby trzeba je później:

class function TDemo.GetAsVariant<T>(const AValue: T): Variant; 
var 
    val: TValue; 
begin 
    val := TValue.From<T>(AValue); 
    case val.Kind of 
    tkEnumeration: 
    begin 
     if val.TypeInfo = TypeInfo(Boolean) then 
     Result := val.AsBoolean 
     else 
     Result := val.AsOrdinal; 
    end 
    else 
    begin 
     Result := val.AsVariant; 
    end; 
    end; 

Możliwe wykorzystanie:

var 
    vValue: Variant; 
begin 
    vValue := TDemo.GetAsVariant<Boolean>(True); 
    Assert(vValue = True); //now vValue is a correct Boolean 

Answer 2

Innym sposobem (testowane XE10)

Var 
    old : variant; 
    val : TValue; 
Begin 
    val := TValue.FromVariant(old); 
End;