Jak odnieść się do klasy z stałej tablicy rekordów?

Question

Mam klasę TiffData, która zawiera abstrakcyjne metody ładowania i wyświetlania danych oraz wiele klas przodków, takich jak TTiffByte, TTiffAscii, TTiffShort, które definiują te metody.

Mam również stałą tablicę lub rekordy, które pozwalają mi wyszukiwać informacje o typach w oparciu o typ danych zarejestrowany w IFD.

Czego nie mogę dowiedzieć się, jak zapisać powiązaną klasę dla każdego elementu tablicy.

type 
    TtiffType = record 
     name : string; 
     bytes : word; 
     data : class; { ? } 
     desc : string; 
    end; 

const 
TiffTypes : array[ 1 .. 18 ] of TTiffType = (

{01} (name: 'byte'; bytes : 1; data: TTiffByte;  { ? } 
     desc: '8-bit unsigned number.' ), 
{02} (name: 'ascii'; bytes : 1; data: TTiffAscii; { ? } 
     desc: '8 bit byte that contains a 7 bit ASCII code; the last byte must be NULL (binary zero)' ), 
{03} (name: 'short'; bytes : 2; data: TTiffShort; { ? } 
     desc: '16-bit (2-byte) unsigned integer.' ), 
... 

Co chciałbym zrobić, to trzymać referencję do klasy w tablicy:

value := TiffTypes[ fldType ].Data.Create; 

value.loadFromOffset(offset); 
Edit1.Text := value.getShortString; 

lub posiadać konstruktor w tablicy:

value := TiffTypes[ fldType ].data; 

value.loadFromFile(f, offset, count); 
InternalRepresentation := TTiffAscii(value.storage); 

Answer 1

Co trzeba to klasa meta.

type 
    TTiffDataClass = class of TiffData; 

Następnie można go używać tak:

TTiffType = record 
    name : string; 
    bytes : word; 
    data : TTiffDataClass; 
    desc : string; 
end; 

Jeśli masz potomkiem TiffData następnie można użyć. Na przykład:

TTiffByte= class(TiffData) 
end; 

To powinno działać:

{01} (name: 'byte'; bytes : 1; data: TTiffByte;  { ? } 
     desc: '8-bit unsigned number.' ), 

Jak Remi powiedział w swojej odpowiedzi, należy uważać z konstruktorów.

Answer 2

od twojej klasy mają wspólną klasę bazową, TiffData, można użyć class of TiffData w rekordzie, np:

type 
    TtiffType = record 
    name : string; 
    bytes : word; 
    data : class of TiffData; // <-- here 
    desc : string; 
    end; 

Korzystanie Data.Create będzie wtedy działać zgodnie z oczekiwaniami, tak długo, jak konstruktor TiffData jest zadeklarowana jako virtual i każdej pochodnej klasy nadpisuje go.

Answer 3

Dzięki Remi i Graymatter! Użyłem informacji z obu odpowiedzi, aby uzyskać następujący wynik. Niemal wszystko inne daje ostrzeżenia, błędy lub wyjątki czasu pracy.

Definiowanie wielu klas do zarządzania różnymi typami danych, wszystkich przodków TTiffData.

Type 

TTiffData = class(TObject) 
    constructor create; virtual; 
    procedure LoadFromIFD(var aValue; Count : LongWord ); virtual; abstract; 
end; 

TTiffShort = class(TTiffData) 
    constructor create; override; 
    procedure LoadFromIFD(var aValue; Count : LongWord ); override; 
end; 

TTiffAscii = class(TTiffData) 
    constructor create; override; 
    procedure LoadFromIFD(var aValue; Count : LongWord ); override; 
end; 

... 

Uwaga: użyłem „override” zamiast „wirtualny” w dzieci, aby zapobiec „metoda«*»ukrywa wirtualną metodę typu bazowego«TTiffData»” ostrzeżeń.

Tablica wygląda następująco:

type 
    TTiffDataClass = class of TTiffData; 

    TtiffType = record 
     name : string; 
     bytes : word; 
     data : TTiffDataClass; 
     desc : string; 
    end; 

const 


    TiffTypes : array[ 1 .. 18 ] of TTiffType = (
{01} (name: 'byte'; bytes : 1; data: TTiffShort; 
     desc: '8-bit unsigned number.' ), 
{02} (name: 'ascii'; bytes : 1; data: TTiffAscii; 
     desc: '8 bit byte that contains a 7 bit ASCII code; the last byte must be NULL (binary zero)' ), 

... 
); 

Zastosowanie:

{ Load } 
    Value := TiffTypes[ fldType ].data.Create; 

    if Indirect then begin 
     Value.LoadFromFile(f, Offset, Count); 
     end 

    else begin 
     ValueLoadFromIFD(Offset, Count); 
     end; 


    { Display } 
    aStringGrid.Cells[ 8, i ] := Value.ShortDisplay;