Zagnieżdżone, jeśli istnieją instrukcje w pliku wsadowym

Question

Ok, próbuję wykonać zagnieżdżone instrukcje IF EXIST, aby sprawdzić obecność kilku folderów. Jeśli pierwszy folder istnieje, ustaw Folder1 na równe 1, a następnie przejdź do Instaluj. To samo dotyczy Folder2, a jeśli żaden z nich nie istnieje, po prostu przejdź do instalacji.

Ale nawet gdy Folder1 nie istnieje, to nadal ustawia% Folder1% na równe 1. Czego mi brakuje/nie robię?

Dzięki!

if exist "c:\folder1" set Folder1=1 
    echo %Folder1% 
    goto install 
else if exist "c:\folder2" set Folder2=1 
    echo %Folder2% 
    goto Install 
else goto Install 

:Install 

Answer 1

dwa podstawowe problemy:

Oświadczenie związek musi być parenthesised. W nawiasach, zmiana wartości zmiennej NIE będzie widoczna, BEZ wykonania SETLOCAL ENABLEDELAYEDEXPANSION - i nawet wtedy musisz użyć! Var! Nie% var%

Więc:

SETLOCAL ENABLEDELAYEDEXPANSION 
if exist "c:\folder1" (
     set Folder1=1 
     echo !Folder1! 
     goto install 
) else if exist "c:\folder2" (
     set Folder2=1 
     echo !Folder2! 
     goto Install 
) else goto Install 

:Install 

lub korzystnie

@ECHO off 
if exist "c:\folder1" (
     set Folder1=1 
     goto install 
) else if exist "c:\folder2" (
     set Folder2=1 
     goto Install 
) else goto Install 

:Install 

SET folder 

Albo jeszcze prościej

@ECHO off 
if exist "c:\folder1" set Folder1=1&goto install 
if exist "c:\folder2" set Folder2=1&goto Install 
:Install 

SET folder 

---

Test:

@ECHO OFF 
setlocal 
SET "folder1=" 
SET "folder2=" 
ECHO.----------No folders 
DIR /b /ad c:\folder* 
CALL :test 
ECHO.----------Folder 1 only 
MD c:\folder1 
DIR /b /ad c:\folder* 
CALL :test 
ECHO.----------Folder 2 only 
RD c:\folder1 
MD c:\folder2 
DIR /b /ad c:\folder* 
CALL :test 
ECHO.----------Both 
MD c:\folder1 
DIR /b /ad c:\folder* 
CALL :test 
RD c:\folder1 
RD c:\folder2 

GOTO :eof 

:test 
if exist "c:\folder1" set Folder1=1&goto install 
if exist "c:\folder2" set Folder2=1&goto Install 
:Install 

SET folder 
SET "folder1=" 
SET "folder2=" 
GOTO :eof 

Ten test tworzy i usuwa dwa katalogi, o których mowa.

Oto wynik:

----------No folders 
----------Folder 1 only 
folder1 
Folder1=1 
----------Folder 2 only 
folder2 
Folder2=1 
----------Both 
folder1 
folder2 
Folder1=1 

Zauważ, że

SET "folder1=" 
    SET "folder2=" 

który jest wykonywany zarówno na początku jak i po każdym raporcie zapewnia, że ​​zmienne środowiskowe w pytaniu są usuwane ze środowiska uniemożliwiają kod podający fałszywe wyniki na nieaktualnych informacjach.

Answer 2

if exist "c:\folder1" (
     set Folder1=1 
     echo %Folder1% 
     goto install 
) if exist "c:\folder2" (
     set Folder2=1 
     echo %Folder2% 
     goto Install 
) else goto Install 

:Install 

Answer 3

Ten kod nie ustawia% folder1% = 1, jeśli folder1 nie istnieje i nie tworzy w tym przypadku żadnych danych wyjściowych. Jeśli Folder1 nie istnieje ORAZ Folder2 istnieje THEN% folder2% ma wartość 1, w przeciwnym razie% folder2% jest pusty. Umieść niezamknięte lewe nawiasy po poleceniu echo, aby wyłączyć wyjście, jeśli zmienna jest pusta.

@echo off &setlocal 
if exist "c:\folder1" set "Folder1=1" 
echo(%Folder1% 
if not defined Folder1 if exist "c:\folder2" set "Folder2=1" 
echo(%Folder2% 
goto Install 

:Install 
endlocal