Porównaj pliki z awk

Question

Witam Mam dwa podobne pliki (oba z 3 kolumnami). Chciałbym sprawdzić, czy te dwa pliki zawierają te same elementy (ale wymienione w różnych zamówieniach). Przede wszystkim chciałbym porównać tylko 1st kolumny

plik1.txt

"aba" 0 0 
"abc" 0 1 
"abd" 1 1 
"xxx" 0 0 

file2.txt

"xyz" 0 0 
"aba" 0 0 
"xxx" 0 0 
"abc" 1 1 

jaki sposób można zrobić to za pomocą awk? Próbowałem się rozejrzeć, ale znalazłem tylko skomplikowane przykłady. Co się stanie, jeśli chcę uwzględnić również pozostałe dwie kolumny w porównaniu? Wynik powinien dać mi liczbę pasujących elementów.

Answer 1

Aby wydrukować wspólne elementy w obu plikach:

$ awk 'NR==FNR{a[$1];next}$1 in a{print $1}' file1 file2 
"aba" 
"abc" 
"xxx" 

Objaśnienie:

NR i FNR są awk zmienne przechowujące całkowitą liczbę rekordów i liczbę rekordów w obecnych plikach odpowiednio (domyślnym rekordem jest linia).

NR==FNR # Only true when in the first file 
{ 
    a[$1] # Build associative array on the first column of the file 
    next # Skip all proceeding blocks and process next line 
} 
($1 in a) # Check in the value in column one of the second files is in the array 
{ 
    # If so print it 
    print $1 
} 

Jeśli chcesz, aby dopasować całe linie następnie użyć $0:

$ awk 'NR==FNR{a[$0];next}$0 in a{print $0}' file1 file2 
"aba" 0 0 
"xxx" 0 0 

lub konkretnego zestawu kolumn:

$ awk 'NR==FNR{a[$1,$2,$3];next}($1,$2,$3) in a{print $1,$2,$3}' file1 file2 
"aba" 0 0 
"xxx" 0 0 

Answer 2

aby wydrukować liczbę pasujących elementów, oto jeden sposób użycia awk:

awk 'FNR==NR { a[$1]; next } $1 in a { c++ } END { print c }' file1.txt file2.txt 

Wyniki wykorzystujące Twój wkład:

3 

---

Jeśli chcesz dodać kolejne kolumny (na przykład, kolumny jeden, dwa i trzy), użyć pseudo-multidimensional array:

awk 'FNR==NR { a[$1,$2,$3]; next } ($1,$2,$3) in a { c++ } END { print c }' file1.txt file2.txt 

wyników przy użyciu danych wejściowych:

2