Praca z bieżącym otwartym e-mailem

Question

Chciałbym uzyskać aktywny otwarty MailItem (bez względu na to, czy jest to nowa wiadomość, czy odebrana poczta). Muszę dodać trochę treści do tej poczty, gdy użytkownik uruchomi moje makro. Korzystam z programu Outlook 2003 i VBA.

Znalazłem: How do you get a reference to the mail item in the current open window in Outlook using VBA? Nie działa jednak, ponieważ TypeName(Application.ActiveWindow) jest ustawiony na nic. Próbowałem też Set Mail = Application.ActiveInspector.currentItem, ale to też nie działa.

Musi być coś, czego nie rozumiem na temat ActiveInspector rzeczy.

Zgodnie z wnioskiem, jest to procedura/makro znajduje się w dedykowanym module wywoływana, gdy użytkownik kliknie na przycisk MENU dodany w metodzie Application_Startup():

Sub myMacro() 
    Dim NewMail As Outlook.MailItem 
    Set NewMail = Application.ActiveInspector.currentItem 
End Sub 

Answer 1

ja nie wiem dokładnie co jest nie tak z twoim kodem. Przede wszystkim jednak nie sprawdzasz, czy nowa, edytowalna wiadomość e-mail jest otwarta. Poniższy proof-of-concept robi dokładnie to, co myślę, że chcesz zrobić: wstawić trochę tekstu do tworzonej e-maila aktywnego. Jeśli nie jest to możliwe, wyświetla okno komunikatu wyjaśniające, dlaczego.

Część, która wstawia tekst, działa tylko wtedy, gdy Word jest używany jako edytor wiadomości e-mail (który będzie ALWAYS be the case in Outlook 2010+). Jeśli nie, musisz przeanalizować i zaktualizować tekst Body lub HTMLBody bezpośrednio.

Sub InsertText() 
    Dim myText As String 
    myText = "Hello world" 

    Dim NewMail As MailItem, oInspector As Inspector 
    Set oInspector = Application.ActiveInspector 
    If oInspector Is Nothing Then 
     MsgBox "No active inspector" 
    Else 
     Set NewMail = oInspector.CurrentItem 
     If NewMail.Sent Then 
      MsgBox "This is not an editable email" 
     Else 
      If oInspector.IsWordMail Then 
       ' Hurray. We can use the rich Word object model, with access 
       ' the caret and everything. 
       Dim oDoc As Object, oWrdApp As Object, oSelection As Object 
       Set oDoc = oInspector.WordEditor 
       Set oWrdApp = oDoc.Application 
       Set oSelection = oWrdApp.Selection 
       oSelection.InsertAfter myText 
       oSelection.Collapse 0 
       Set oSelection = Nothing 
       Set oWrdApp = Nothing 
       Set oDoc = Nothing 
      Else 
       ' No object model to work with. Must manipulate raw text. 
       Select Case NewMail.BodyFormat 
        Case olFormatPlain, olFormatRichText, olFormatUnspecified 
         NewMail.Body = NewMail.Body & myText 
        Case olFormatHTML 
         NewMail.HTMLBody = NewMail.HTMLBody & "<p>" & myText & "</p>" 
       End Select 
      End If 
     End If 
    End If 
End Sub 

Answer 2

Czy masz na myśli aktualnie wybraną wiadomość? W takim przypadku należy użyć kolekcji Application.ActiveExplorer.Selection, a nie Application.ActiveInspector.CurrentItem.

Answer 3

  ' 
      Dim myOlExp As Outlook.Explorer 
      Dim myOlSel As Outlook.Selection 

      Set myOlExp = Application.ActiveExplorer 
      Set myOlSel = myOlExp.Selection 
      'MsgBox myOlSel.item(1) 


      Dim selectedFolder As Outlook.MAPIFolder 
       Set selectedFolder = myOlExp.CurrentFolder 
      Dim itemMessage As String 
       itemMessage = "Item is unknown." 


      Dim expMessage As String 
      expMessage = "Your current folder is " & selectedFolder.Name & "." & vbCrLf 

      If myOlSel.Count > 0 Then 

          Dim selObject As Object 
          Set selObject = myOlSel.item(1) 

          If (TypeOf selObject Is Outlook.mailItem) Then 
           Dim mailItem As Outlook.mailItem 
           Set mailItem = selObject 
           itemMessage = "The item is an e-mail message." & " The subject is " & mailItem.Subject & "." 
           mailItem.Display (False) 

          ElseIf (TypeOf selObject Is Outlook.contactItem) Then 
           Dim contactItem As Outlook.contactItem 
           Set contactItem = selObject 
           itemMessage = "The item is a contact." & " The full name is " & contactItem.Subject & "." 
           contactItem.Display (False) 

          ElseIf (TypeOf selObject Is Outlook.AppointmentItem) Then 
           Dim apptItem As Outlook.AppointmentItem 
           Set apptItem = selObject 
           itemMessage = "The item is an appointment." & apptItem.Subject & "." 

          ElseIf (TypeOf selObject Is Outlook.taskItem) Then 
           Dim taskItem As Outlook.taskItem 
           Set taskItem = selObject 
           itemMessage = "The item is a task." & " The body is " & taskItem.Body & "." 
          ElseIf (TypeOf selObject Is Outlook.meetingItem) Then 
           Dim meetingItem As Outlook.meetingItem 
           Set meetingItem = selObject 
           itemMessage = "The item is a meeting item. " & "The subject is " & meetingItem.Subject & "." 
          End If 
         End If 
         expMessage = expMessage & itemMessage 
        MsgBox (expMessage) 
      End Sub