TRIM funkcja/usuwanie spacji z komórek przy użyciu VBA

Question

Korzystam z poniższego kodu, aby przyciąć niektóre "puste komórki", które zawierają spację. Chodzi o to, że zajmuje to zbyt dużo czasu, podobnie jak pętla do każdej komórki. Chcę usunąć spacje (te na początku i końcu, a nie na środku) ze wszystkich komórek.

Czy istnieje łatwiejszy sposób, w jaki mogę zastosować wszystkie naraz?

For a = 1 To ScenarioTableLastRow 
    For f = 1 To ScenarioTableLastColumn 

     If Cells(a, f) <> "" Then 
      Cells(a, f) = Excel.Application.Trim(Cells(a, f)) 
     End If 

    Next f 
Next a 

Answer 1

Dostaniesz znacznie lepszą wydajność kopiowanie danych do tablicy, i pracy na tablicy, a następnie umieszczając dane z powrotem do zakresu.

Ponadto nie należy używać Excel.Application.Trim. To jest składnia Excel 95 i późno-wywołanie z nieoczekiwaną obsługą błędów. VBA ma wbudowaną funkcję Trim - jest około 10 razy szybsza i zapewnia IntelliSense.

Sub test() 

    'Assuming ScenarioTable is a range 
    Dim ScenarioTable As Range 
    Set ScenarioTable = Range("ScenarioTable") 

    'I assume your range might have some formulas, so... 
    'Get the formulas into an array 
    Dim v As Variant 
    v = ScenarioTable.Formula 

    Dim a As Long 
    Dim f As Long 
    'Then loop over the array 
    For a = LBound(v, 1) To UBound(v, 1) 
     For f = LBound(v, 2) To UBound(v, 2) 
      If Not IsEmpty(v(a, f)) Then 
       v(a, f) = VBA.Trim(v(a, f)) 
      End If 
     Next f 
    Next a 
    'Insert the results 
    ScenarioTable.Formula = v 
End Sub 

Answer 2

Czy to na całego zakresu naraz przy użyciu wersji tablicy Excel Trim:

myRange.Value = Application.Trim(myRange.Value) 

Korzystanie jedyne zmienne widoczne w kodzie, byłoby:

With Range(Cells(1,1), Cells(ScenarioTableLastRow, ScenarioTableLastColumn)) 
    .Value = Application.Trim(.Value) 
End With