Jak mogę sprawdzić rozmiar pliku w skrypcie wsadowym Windows?

Question

Chcę mieć plik wsadowy, który sprawdza, co jest w pliku filesize.

Jeśli jest większy niż %somany% kbytes,, powinien przekierować z GOTO do innego miejsca.

Przykład:

[check for filesize] 
IF %file% [filesize thing Bigger than] GOTO No 
echo Great! Your filesize is smaller than %somany% kbytes. 
pause 
exit 
:no 
echo Um... You have a big filesize. 
pause 
exit 

Answer 1

Jeśli nazwa pliku jest używana jako parametr do pliku wsadowego, co potrzebne jest %~z1 (1 oznacza pierwszy parametr)

Jeśli nazwa pliku nie jest parametrem, można zrobić coś takiego:

@echo off 
setlocal 
set file="test.cmd" 
set maxbytesize=1000 

FOR /F "usebackq" %%A IN ('%file%') DO set size=%%~zA 

if %size% LSS %maxbytesize% (
    echo.File is ^< %maxbytesize% bytes 
) ELSE (
    echo.File is ^>= %maxbytesize% bytes 
) 

Answer 2

tylko pomysł:

można uzyskać rozmiar pliku przez polecenie działa "dir":

>dir thing 

Potem znowu powraca tak wiele rzeczy.

Może uda się ją pobrać, jeśli jej szukasz.

Ale nie jestem pewien.

Answer 3

Jak zwykle, VBScript jest dostępna do użycia .....

Set objFS = CreateObject("Scripting.FileSystemObject") 
Set wshArgs = WScript.Arguments 
strFile = wshArgs(0) 
WScript.Echo objFS.GetFile(strFile).Size & " bytes" 

Zapisz filesize.vbs i wprowadzić w wierszu poleceń:

C:\test>cscript /nologo filesize.vbs file.txt 
79 bytes 

Skorzystaj z for pętla (w batch), aby uzyskać wynik powrotu.

Answer 4

Jeśli twój %file% jest parametrem wejściowym, możesz użyć %~zN, gdzie N jest numerem parametru.

E.g. test.bat zawierający

@echo %~z1 

wyświetla rozmiar pierwszego parametru, więc jeśli używasz „test myFile.txt” to wyświetli rozmiaru odpowiedniego pliku.

Answer 5

%~z1 rozwija się do rozmiaru pierwszego argumentu pliku wsadowego. Zobacz

C:\> call /? 

i

C:\> if /? 

prosty przykład:

@ECHO OFF 
SET SIZELIMIT=1000 
SET FILESIZE=%~z1 

IF %FILESIZE% GTR %SIZELIMIT% Goto No 

ECHO Great! Your filesize is smaller than %SIZELIMIT% kbytes. 
PAUSE 
GOTO :EOF 

:No 
ECHO Um ... You have a big filesize. 
PAUSE 
GOTO :EOF 

Answer 6

Właśnie zobaczyłem to stare pytanie, aby sprawdzić, czy system Windows ma coś wbudowanego. To, czego nie wiedziałem, nie dotyczy mnie. Skończyło się na tym, że jeden liniowiec Perla:

@echo off 

set yourfile=output.txt 
set maxsize=10000 

perl -e "-s $ENV{yourfile} > $ENV{maxsize} ? exit 1 : exit 0" 
rem if %errorlevel%. equ 1. goto abort 
if errorlevel 1 goto abort 

echo OK! 
exit /b 0 

:abort 
echo Bad! 
exit /b 1 

Answer 7

To było moje rozwiązanie do oceny rozmiarów plików bez użycia VB/perl/etc.i wystaje z okna rodzime poleceń powłoki:

FOR /F "tokens=4 delims= " %%i in ('dir /-C %temp% ^| find /i "filename.txt"') do ( 
    IF %%i GTR 1000000 ( 
     echo filename.txt filesize is greater than 1000000 
    ) ELSE ( 
     echo filename.txt filesize is less than 1000000 
    ) 
) 

Nie najczystszym rozwiązanie, ale dostaje zadanie.

Answer 8

Innym przykładem

FOR %I in (file1.txt) do @ECHO %~zI 

Answer 9

wolę używać funkcji DOS. Czuję się dla mnie czystszy.

SET SIZELIMIT=1000 
CALL :FileSize %1 FileSize 
IF %FileSize% GTR %SIZELIMIT% Echo Large file 

GOTO :EOF 

:FileSize 
SET %~2=%~z1 

GOTO :EOF 

Answer 10

Utwórz plik wsadowy jednego wiersza zawierającego GetFileSize.bat

GetFileSize=%~z1 

następnie nazwać

call GetFileSize myfile.txt 
if (%GetFileSize) ==()  goto No_File 
if (%GetFileSize) == (0) goto No_Data 
if (%GetFileSize) GTR 1000 goto Too_Much_Data 
rem Etc. 

Można nawet utworzyć plik testowy na bieżąco, aby wyeliminować brzydkie wymaganego pliku , zanotuj podwójny procent w wyciągu z echa:

echo set GetFileSize=%%~z1 > %temp%\GetFileSize.bat 
call %temp%\GetFileSize myfile.txt 
if (%GetFileSize) GTR 1000 goto Too_Much_Data 
rem etc 

To ostatnie rozwiązanie to antispaghetti. Tak miło. Jednak więcej zapisuje na dysku. Sprawdź liczbę użytków.

Answer 11

Należy zwrócić uwagę na limit INT32 dla partii: "Nieprawidłowy numer. Liczby są ograniczone do 32 bitów dokładności. "

Spróbuj wykonać następujące oświadczenia:

IF 2147483647 GTR 2147483646 echo A is greater than B (will be TRUE) 
IF 2147483648 GTR 2147483647 echo A is greater than B (will be FALSE!) 

Dowolna liczba większa niż wartość maksymalna Int32 złamie skrypt! Ponieważ rozmiar pliku jest mierzony w bajtach, skrypty obsługują maksymalny rozmiar pliku około 255.9999997615814 MB!

Answer 12

Lubię @Anders odpowiedzieć, ponieważ wyjaśnienie sekretnego sosu% ~ z1. Jednak, jak wskazano, działa to tylko wtedy, gdy nazwa pliku zostanie przekazana jako pierwszy parametr do pliku wsadowego.

@Anderowie rozwiązali ten problem, używając FOR, która jest świetną poprawką 1-linerową na , ale jest nieco trudniejsza do odczytania.

Zamiast tego możemy wrócić do prostszej odpowiedzi z% ~ z1 przy użyciu CALL. Jeśli masz nazwę pliku zapisanego w zmiennej środowiskowej stanie się % 1 jeśli używasz go jako parametr do funkcji w pliku wsadowym:

@echo off 
setlocal 
set file=test.cmd 
set maxbytesize=1000 

call :setsize %file% 

if %size% lss %maxbytesize% (
    echo File is less than %maxbytesize% bytes 
) else (
    echo File is greater than %maxbytesize% bytes 
) 
goto :eof 

:setsize 
set size=%~z1 
goto :eof 

Answer 13

Po kilku „próbować i test” iteracji I” już znalazł sposób (jeszcze nie prezentujemy tutaj), aby uzyskać rozmiar pliku w zmiennej cyklu (a nie parametrów wiersza poleceń):

for %%i in (*.txt) do (
    echo %%~z%i 
)