Jak uzyskać określoną liczbę losowych elementów z kolekcji w Smalltalk?

Question

Jak mogę elegancko uzyskać konkretną liczbę (> 1) różnych, losowych elementów z kolekcji?

Answer 1

To jest coś, co myślę, że wygląda bardziej lub mniej ładne, ale nie jest tak efektywny, jak to może być:

yourCollection asSet asOrderedCollection shuffled first: numberOfElements 

Answer 2

Rozważmy następujący fragment kodu

sample: anInteger from: aCollection using: aGenerator 
    | sample | 
    sample := Set new: anInteger. 
    [sample size = anInteger] 
    whileFalse: [ | element | 
     element := aCollection atRandom: aGenerator. 
     sample add: element]. 
    ^sample asArray 

Kilka uwag

• Wyraźny generator: To jawnie używa danego generatora, tj. Instancji o numerze Random, którą nazwałem aGenerator. Ze względów matematycznych, jeśli pobierasz próbki do swojej aplikacji, wszystkie powinny używać tego samego generatora w całym programie. Zapewni to także dodatkową korzyść: zapisz i później przywróć wersję seed, a będziesz w stanie odtworzyć poprzednie "losowe" zachowanie systemu, co jest dobre do testowania.

• No check dostępność: kod nie sprawdza, że ​​jest możliwe, aby uzyskać żądaną próbkę, co byłoby, gdyby aCollection nie posiada przynajmniej anInteger różnych elementów.

• Kod bez kodowania: Metoda powinna trafić do niektórych klas.

Na przykład:

Random >> sample: anInteger from: aCollection 
    | sample | 
    sample := Set new: anInteger. 
    [sample size = anInteger] 
    whileFalse: [ | element | 
     element := aCollection atRandom: self. 
     sample add: element]. 
    ^sample asArray 

UPDATE

Oto innego podejścia:

Random >> remove: anInteger from: aCollection 
    | sample | 
    sample := OrderedCollection new: anInteger. 
    anInteger timesRepeat: [| index element | 
    index := aCollection size atRandom: self. 
    element := aCollection removeAt: index. 
    sample add: element]. 
    ^sample 

Komentarz

Zwykle, gdy chcemy próbkować bez powtórzeń, chcemy również usunąć elementy z kolekcji, ponieważ losowo je wybieramy. W takich przypadkach często zdarza się, że zbiór nie zawiera powtórzeń.