Podstawowe użycie wielu GPU

Question

Jak mogę użyć dwóch urządzeń, aby poprawić na przykład działanie następującego kodu (suma wektorów)? Czy można korzystać z większej liczby urządzeń "w tym samym czasie"? Jeśli tak, w jaki sposób mogę zarządzać przydziałami wektorów w pamięci globalnej różnych urządzeń?

#include <stdio.h> 
#include <stdlib.h> 
#include <math.h> 
#include <time.h> 
#include <cuda.h> 

#define NB 32 
#define NT 500 
#define N NB*NT 

__global__ void add(double *a, double *b, double *c); 

//=========================================== 
__global__ void add(double *a, double *b, double *c){ 

    int tid = threadIdx.x + blockIdx.x * blockDim.x; 

    while(tid < N){ 
     c[tid] = a[tid] + b[tid]; 
     tid += blockDim.x * gridDim.x; 
    } 

} 

//============================================ 
//BEGIN 
//=========================================== 
int main(void) { 

    double *a, *b, *c; 
    double *dev_a, *dev_b, *dev_c; 

    // allocate the memory on the CPU 
    a=(double *)malloc(N*sizeof(double)); 
    b=(double *)malloc(N*sizeof(double)); 
    c=(double *)malloc(N*sizeof(double)); 

    // allocate the memory on the GPU 
    cudaMalloc((void**)&dev_a, N * sizeof(double)); 
    cudaMalloc((void**)&dev_b, N * sizeof(double)); 
    cudaMalloc((void**)&dev_c, N * sizeof(double)); 

    // fill the arrays 'a' and 'b' on the CPU 
    for (int i=0; i<N; i++) { 
     a[i] = (double)i; 
     b[i] = (double)i*2; 
    } 

    // copy the arrays 'a' and 'b' to the GPU 
    cudaMemcpy(dev_a, a, N * sizeof(double), cudaMemcpyHostToDevice); 
    cudaMemcpy(dev_b, b, N * sizeof(double), cudaMemcpyHostToDevice); 

    for(int i=0;i<10000;++i) 
     add<<<NB,NT>>>(dev_a, dev_b, dev_c); 

    // copy the array 'c' back from the GPU to the CPU 
    cudaMemcpy(c, dev_c, N * sizeof(double), cudaMemcpyDeviceToHost); 

    // display the results 
    // for (int i=0; i<N; i++) { 
    //  printf("%g + %g = %g\n", a[i], b[i], c[i]); 
    // } 
    printf("\nGPU done\n"); 

    // free the memory allocated on the GPU 
    cudaFree(dev_a); 
    cudaFree(dev_b); 
    cudaFree(dev_c); 
    // free the memory allocated on the CPU 
    free(a); 
    free(b); 
    free(c); 

    return 0; 
} 

Z góry dziękuję. Michele

Answer 1

Od czasu wydania CUDA 4.0, obliczenia wieloprocesorowe typu, o który pytasz, są stosunkowo łatwe. Wcześniej konieczne byłoby użycie wielowątkowej aplikacji hosta z jednym wątkiem hosta na układ GPU i pewnego rodzaju system komunikacji między wątkami w celu użycia wielu GPU w tej samej aplikacji hosta.

Teraz jest to możliwe, aby zrobić coś takiego dla części alokacji pamięci w kodzie gospodarza:

double *dev_a[2], *dev_b[2], *dev_c[2]; 
const int Ns[2] = {N/2, N-(N/2)}; 

// allocate the memory on the GPUs 
for(int dev=0; dev<2; dev++) { 
    cudaSetDevice(dev); 
    cudaMalloc((void**)&dev_a[dev], Ns[dev] * sizeof(double)); 
    cudaMalloc((void**)&dev_b[dev], Ns[dev] * sizeof(double)); 
    cudaMalloc((void**)&dev_c[dev], Ns[dev] * sizeof(double)); 
} 

(disclaimer: napisany w przeglądarce, nigdy skompilowany, nie testowane, wykorzystanie na własne ryzyko).

Podstawową ideą jest tutaj użycie cudaSetDevice do wybierania między urządzeniami podczas wstępnego wykonywania operacji na urządzeniu. Tak więc w powyższym fragmencie założyłem dwa procesory graficzne i przydzieloną pamięć na każde [(N/2) podwojenie na pierwszym urządzeniu i N- (N/2) na drugim].

Przeniesienie danych z hosta do urządzenia może być tak proste, jak:

// copy the arrays 'a' and 'b' to the GPUs 
for(int dev=0,pos=0; dev<2; pos+=Ns[dev], dev++) { 
    cudaSetDevice(dev); 
    cudaMemcpy(dev_a[dev], a+pos, Ns[dev] * sizeof(double), cudaMemcpyHostToDevice); 
    cudaMemcpy(dev_b[dev], b+pos, Ns[dev] * sizeof(double), cudaMemcpyHostToDevice); 
} 

(Zastrzeżenie: napisany w przeglądarce, nigdy skompilowany, nie testowane, wykorzystanie na własne ryzyko).

Jądro sekcję kodu uruchomienie mógłby wtedy wyglądać następująco:

for(int i=0;i<10000;++i) { 
    for(int dev=0; dev<2; dev++) { 
     cudaSetDevice(dev); 
     add<<<NB,NT>>>(dev_a[dev], dev_b[dev], dev_c[dev], Ns[dev]); 
    } 
} 

(Zastrzeżenie: pisemnej w przeglądarce, nigdy skompilowany, nie testowane, wykorzystanie na własne ryzyko).

Zauważ, że dodałem dodatkowy argument do twojego wywołania jądra, ponieważ każda instancja jądra może zostać wywołana z inną liczbą elementów tablicy do przetworzenia. Zostawię to tobie, aby opracować wymagane modyfikacje. Ale znowu podstawowa idea jest taka sama: użyj cudaSetDevice, aby wybrać dany GPU, a następnie uruchom jądra na nim w normalny sposób, przy czym każde jądro otrzymuje własne unikalne argumenty.

Powinieneś być w stanie połączyć te części, aby stworzyć prostą aplikację dla wielu GPU. Istnieje wiele innych funkcji, które mogą być używane w najnowszych wersjach CUDA i sprzętowych, aby pomóc wielu aplikacjom GPU (jak ujednolicone adresowanie, urządzenia peer-to-peer), ale to powinno wystarczyć. W pakiecie CUDA SDK znajduje się również prosta aplikacja muLti-GPU, w której możesz przejrzeć więcej pomysłów.