Jak zautomatyzować tworzenie nowych obiektów docelowych XCode z Applescript/Automator/Shell Script

Question

Obecnie pracuję nad sposobem automatyzacji procesu dodawania nowych obiektów do moich projektów XCode. Jeden cel musi zostać dodany do wielu projektów XCode, a każdy cel w innym projekcie wymaga tych samych plików źródłowych, które mają zostać dodane, tych samych grup do przechowywania plików źródłowych w projekcie XCode i tych samych ustawień kompilacji. Robienie tego ręcznie może zająć trochę czasu i jest bardzo podatne na błędy ludzkie, i muszę to robić dość często. Napisałem już skrypt do generowania nowych plików źródłowych, kopiowania ich do folderów systemowych, edytowania plików źródłowych z nowymi informacjami itp., Ale teraz muszę zautomatyzować część XCode.

To podsumowuje to, co chcę osiągnąć mój automatyzacja:

Otwórz projekt XCode na /this/path/project.xcodeproj

Duplikat istniejący cel i zmienić jego nazwę

edycję Build Ustawienia nowego celu

Dodaj grupę do sekcji source i zasobów, a następnie zmień je

Dodaj źródło f iles do grup i dodać plik do nowego docelowa

Zamknij XCode

Idealnie chcę to uruchomić z mojego skryptu Bourne Shell, wiem, że można uruchomić przepływ pracy Automator stamtąd. Nie jestem pewien, jakie jest najlepsze podejście do tego, jakiekolwiek pomysły? Z góry dzięki :-)

Answer 1

zacznę z tego skryptu (dla Xcode 4.2.1),

• Otwórz projekt XCode na /this/path/project.xcodeproj (zrobione)
• Duplikat istniejący cel i zmienić jego nazwę (nie zaimplementowane)
• edytować ustawienia kompilacji nowy cel (zrobione)
• dodać grupę do sekcji source i Zasobów, następnie zmień je (zrobione)
• Dodaj pliki źródłowe do grupy i dodaj t on złożyć do nowej docelowej (częściowo)
• Close XCode (zrobione)

!/usr/bin/osascript

# Reference: AppleScript Editor -> File -> Open Directory ... -> Xcode 4.2.1 

# http://vgable.com/blog/2009/04/24/how-to-check-if-an-application-is-running-with-applescript/ 
on ApplicationIsRunning(appName) 
    tell application "System Events" to set appNameIsRunning to exists (processes where name is appName) 
    return appNameIsRunning 
end ApplicationIsRunning 

if not ApplicationIsRunning("Xcode") then 
    log ("Launching Xcode ...") 
    launch application id "com.apple.dt.Xcode" 
    delay 5 
else 
    log("Xcode is already running ...") 
end if 

set project_path to "/PATH/TO/YOUR_PROJECT.xcodeproj" 
log ("Open an XCode project at " & project_path) 

set _project_name to (do shell script "echo $(basename " & project_path & ") | sed -e 's/.xcodeproj//'") 
log ("project_name set to " & _project_name) 

set _target_name to "YOUR_TARGET" 

tell application id "com.apple.dt.Xcode" 
    set _project_file to (POSIX file project_path as alias) 
    open _project_file 
    # load documentation set with path path_to_project display yes 
    set _workspace to active workspace document 
    set _project to first item of (projects of _workspace whose name = _project_name) 
    set _target to first item of (targets of _project whose name = _target_name) 

    # as this won't work, cannot event resort to system event 
    # duplicate _target with properties {name:_target_name & "_clone"} 
    # make new build configuration with data build configurations of _target with properties {name:_target_name & "_clone"} 
    # activate 

    log ("Edit the Build Settings of the new target") 
    set _build_configuration to first item of (build configurations of _target whose name = "Debug") 
    set value of build setting "PRODUCT_NAME" of _build_configuration to "KeySING" 

    # http://lists.apple.com/archives/xcode-users//2008/Feb/msg00497.html 
    log ("Add a group to the Source and Resources section, then rename them") 
    set _new_group_name to "groupX" 
    tell root group of _project 
     set _groups to (get groups whose name = _new_group_name) 
     if (length of _groups) = 0 then 
      set _new_group to make new group with properties {name:_new_group_name, path:_new_group_name, path type:group relative} 
     else 
      set _new_group to first item of _groups 
     end if 

     log ("Add source files to the groups, and add the file to the new Target") 
     tell _new_group 
      set _new_file_name to "whatever.h" 
      set _new_files to get (file references whose name = _new_file_name) 
      if (length of _new_files) = 0 then 
       # Xcode crashes 
       # make new file reference with properties ¬ 
       #  {name:_new_file_name, file encoding:utf8, path type:group relative,¬ 
       #  path:_new_file_name} 
      end if 
     end tell 
    end tell 

    log ("Close XCode") 
    quit 

end tell