Pętla zależności obiektu Oracle

Question

Mam problem, kiedy próbuję skompilować mój projekt w bazie danych Oracle. Aby było prostsze, mam trzy obiekty: 2 pakiety (UTILS i TYPY) i 1 widok (VIEW).

Pakiet UTILS używa typów zdefiniowanych w TYPACH paczki. Pakiet TYPES używa VIEW jako podstawy dla jednego z typów. A VIEW używa funkcji z pakietu UTILS w swoim skrypcie. Kiedy próbuję wprowadzić zmiany w jednym z tych obiektów, nie mogę skompilować, ponieważ wszystko jest w nieprawidłowym stanie. Powstaje więc pewna pętla zależności obiektów.

Proszę, pomóż mi rozwiązać ten problem.

Na przykład, czy mimo to istnieje potrzeba skompilowania poniższego kodu? Każdy obiekt jest indywidualnie poprawny pod względem składni, ale jak można je wszystkie zestawiać razem?

create or replace package my_types is 
    type type1 is table of number; 
    type type2 is table of my_view%rowtype; 
end; 
/

create or replace package my_utils is 
    function get_1 return number; 
    procedure do_something(parameter my_types.type2); 
end; 
/

create or replace package body my_utils is 
    function get_1 return number is 
    begin 
     return 1; 
    end; 

    procedure do_something(parameter my_types.type2) is 
    begin 
     null; 
    end; 
end; 
/

create or replace force view my_view as 
select * from dual 
where 1 = my_utils.get_1(); 

exec dbms_utility.compile_schema(user, false); 

select object_name from user_objects where status <> 'VALID'; 

Answer 1

Jeśli nie chcesz/nie możesz podzielić paczki ani widoku, zawsze możesz najpierw utworzyć atrapową wersję swojego widoku, skompilować pakiety i później stworzyć "prawdziwy" widok:

create or replace package my_types is 
    type type1 is table of number; 
    type type2 is table of my_view%rowtype; 
end; 
/

create or replace package my_utils is 
    function get_1 return number; 
    procedure do_something(parameter my_types.type2); 
end; 
/

create or replace package body my_utils is 
    function get_1 return number is 
    begin 
     return 1; 
    end; 

    procedure do_something(parameter my_types.type2) is 
    begin 
     null; 
    end; 
end; 
/

create or replace force view my_view as 
select * from dual; 

exec dbms_utility.compile_schema(user, false); 

create or replace force view my_view as 
select * from dual 
where 1 = my_utils.get_1(); 

select object_name from user_objects where status <> 'VALID'; 

Answer 2

Jeśli złamiesz widok w dwóch widokach, można złamać cykliczną zależność:

create or replace view my_view_1 
as select * from dual; 

create or replace package my_types is 
    type type1 is table of number; 
    type type2 is table of my_view_1%rowtype; 
end; 
/

create or replace package my_utils is 
    function get_1 return number; 
    procedure do_something(parameter my_types.type2); 
end; 
/

create or replace package body my_utils is 
    function get_1 return number is 
    begin 
     return 1; 
    end; 

    procedure do_something(parameter my_types.type2) is 
    begin 
     null; 
    end; 
end; 
/

create or replace view my_view as 
select * from my_view_1 
where 1 = my_utils.get_1(); 

EDIT: Inną możliwością jest przełamanie my_utils pakiet na dwie części:

create or replace package my_utils_1 is 
    function get_1 return number; 
end; 
/
create or replace package body my_utils_1 is 
    function get_1 return number is 
    begin 
     return 1; 
    end; 
end; 
/

create or replace view my_view as 
select * from dual 
where 1 = my_utils_1.get_1(); 

create or replace package my_types is 
    type type1 is table of number; 
    type type2 is table of my_view%rowtype; 
end; 
/

create or replace package my_utils_2 is 
    procedure do_something(parameter my_types.type2); 
end; 
/
create or replace package body my_utils_2 is 
    procedure do_something(parameter my_types.type2) is 
    begin 
     null; 
    end; 
end; 
/

Answer 3

Nie używałbym typów paczkowych i% ROWTYPE. Nie są to standardowe SQL i mogą być zastąpione przez Structured Types

create or replace view my_view_1 
as select * from dual; 

create or replace type type1 as table of number; 
create or replace type type2 as object (DUMMY VARCHAR2(1 byte)); 
create or replace type table_type2 as table of type2; 

create or replace package my_utils is 
    function get_1 return number; 
    procedure do_something(parameter table_type2); 
end; 
/

create or replace package body my_utils is 
    function get_1 return number is 
    begin 
     return 1; 
    end; 

    procedure do_something(parameter table_type2) is 
    begin 
     null; 
    end; 
end; 
/

create or replace view my_view as 
select * from my_view_1 
where 1 = my_utils.get_1();