CFC AngularJS i ColdFusion

Question

Próbuję podnieść AngularJS z powrotem do ColdFusion i uruchamiam kilka blokad dróg. Modyfikuję ich aplikację "Do zrobienia" http://angularjs.org/ za pomocą bazy danych galerii sztuki CF. Próbuję połączyć CFC ColdFusion z aplikacją Angular, używając AJAX.

Poniżej jest moje artists.cfc:

<cfcomponent> 

<cffunction name="getArtists" access="remote" > 
    <cfargument name="firstName" default=""> 
    <cfargument name="lastName" default=""> 

    <cfquery name="getArtists_sql" datasource="cfartgallery"> 
     SELECT 
      firstname as text, 
      lastname as done 
     FROM artists 
     WHERE 0=0 
    <cfif firstName neq ""> 
     AND ucase(firstname) like ucase('%#FIRSTNAME#%') 
    </cfif> 
    <cfif lastName neq ""> 
     OR ucase(lastname) like ucase('%#LASTNAME#%')  
    </cfif> 
    </cfquery> 

    <cfreturn getArtists_sql> 
</cffunction> 

</cfcomponent> 

nazywam CFC za pomocą angularjs z następującego kodu:

function TodoCtrl($scope, $http) { 
    $http.get('cfc/artists.cfc?method=getArtists&returnformat=json'). 
     success(function (response) { 
      $scope.todos = data.DATA; 
    }). 
     error(function (data) { 
      $scope.todos = data; 
     }); 
} 

wiem, że dostanę odpowiedź z powrotem. Poniżej narzędzia programistyczne na ciąg JSON Chrome wraca do mnie:

{ 
"COLUMNS": 
    ["TEXT","DONE"], 
"DATA":[ 
    ["Aiden","Donolan"], 
    ["Austin","Weber"], 
    ["Elicia","Kim"], 
    ["Jeff","Baclawski"], 
    ["Lori","Johnson"], 
    ["Maxwell","Wilson"], 
    ["Paul","Trani"], 
    ["Raquel","Young"], 
    ["Viata","Trenton"], 
    ["Diane","Demo"], 
    ["Anthony","Kunovic"], 
    ["Ellery","Buntel"], 
    ["Emma","Buntel"], 
    ["Taylor Webb","Frazier"], 
    ["Mike","Nimer"] 
]} 

To nie wygląda jak notacji Kątowymi stosowanych w ich demo:

[ 
{text:'learn angular', done:true}, 
{text:'build an angular app', done:false} 
] 

Czy ktoś może wskazać mi w dobrym kierunku, aby jak mogę zrobić, żeby to działało poprawnie? Idealnie, chciałbym zachować nienaruszoną CFC, aby można ją było ponownie wykorzystać dla innej aplikacji, więc manipulacja JSON musiałaby zostać wykonana na końcu Javascript.

Answer 1

Domyślnie Coldfusion używa innej notacji JSON, niż może być używana. Nazwy kolumn są przechowywane w jednej tablicy, podczas gdy dane są przechowywane w innej. Zaimplementowane rozwiązanie wymagało zmiany CFquery na tablicę. Następnie JSONEnkodując tę ​​tablicę.

Będziesz potrzebował tej funkcji tutaj:

<cffunction name="QueryToArray" access="public" returntype="array" output="false"hint="This turns a query into an array of structures."> 
    <cfargument name="Data" type="query" required="yes" /> 

    <cfscript> 
     // Define the local scope. 
     var LOCAL = StructNew(); 

     // Get the column names as an array. 
     LOCAL.Columns = ListToArray(ARGUMENTS.Data.ColumnList); 

     // Create an array that will hold the query equivalent. 
     LOCAL.QueryArray = ArrayNew(1); 

     // Loop over the query. 
     for (LOCAL.RowIndex = 1 ; LOCAL.RowIndex LTE ARGUMENTS.Data.RecordCount ; LOCAL.RowIndex = (LOCAL.RowIndex + 1)){ 

     // Create a row structure. 
     LOCAL.Row = StructNew(); 

     // Loop over the columns in this row. 
     for (LOCAL.ColumnIndex = 1 ; LOCAL.ColumnIndex LTE ArrayLen(LOCAL.Columns) ; LOCAL.ColumnIndex = (LOCAL.ColumnIndex + 1)){ 

     // Get a reference to the query column. 
     LOCAL.ColumnName = LOCAL.Columns[ LOCAL.ColumnIndex ]; 

     // Store the query cell value into the struct by key. 
     LOCAL.Row[ LOCAL.ColumnName ] = ARGUMENTS.Data[ LOCAL.ColumnName ][ LOCAL.RowIndex ]; 

     } 

     // Add the structure to the query array. 
     ArrayAppend(LOCAL.QueryArray, LOCAL.Row); 

     } 

     // Return the array equivalent. 
     return(LOCAL.QueryArray); 

    </cfscript> 
</cffunction> 

I wtedy Twój zysk będzie wyglądać następująco:

<cfreturn SerializeJson(QueryToArray(getArtists_SQL),true)> 

Rzeczą do zapamiętania jest to, że obiekt CFquery zawiera inne właściwości, takie jak RecordCount .. i najprawdopodobniej JS chce tylko danych. Nie wiem, czy istnieje bardziej eleganckie rozwiązanie tego problemu, ale jest to rozwiązanie, na które trafiliśmy, gdy mieliśmy podobny problem z JQgrid.

Answer 2

Aby przejść do powyższej odpowiedzi od Blaise. Używając queryToArray używam parametrów columnList obiektu zapytania. Tak jest w przypadku aliasów kolumnowych. W przeciwnym razie będą to wszystkie ograniczenia w twoim JSON

/**queryToArray 
* utility method to keep the code dry. 
* @hint does exactly what the name says, take a query, makes it an array of stucts 
* @hint columnLabels pass in a list of columnLabels to just return those columns 
*/ 
public array function queryToArray(required query data, any columnLabels=false){ 
    var columns = listToArray(arguments.data.columnList); 
    if(arguments.columnLabels != false){ 
      columns = listToArray(arguments.columnLabels); 
    } 

    var queryArray = arrayNew(1); 

    for(i=1; i <= arguments.data.RecordCount; i++){ 

      row = StructNew(); 
      for (j=1; j <= ArrayLen(columns); j++){ 
       columnName = columns[j]; 
     row[columnName] = arguments.data[columnName][i]; 
      } 
      arrayAppend(queryArray, row); 
    } 
    return(queryArray); 
}