Globalne stałe w Groovy

Question

Często deklaruje się stałe na początku skryptu, do którego można się odwoływać w dowolnym miejscu skryptu. W Groovy wygląda na to, że jeśli zadeklarujesz stałą używając final, to nie będzie ona dostępna w zakresach potomnych. Jakie jest rozwiązanie tego bardzo podstawowego i powszechnego wymogu? Obejście, które mam teraz, polega na utworzeniu zmiennej niezwiązanej, ale nie jest ona stała i nie jest elegancka.

Answer 1

Groovy tak naprawdę nie ma zasięgu globalnego. Kiedy masz fajny skrypt, który nie deklaruje klasy, pośrednio utknie w klasie z nazwą skryptu. Zatem zmienne końcowe w zasięgu najwyższego poziomu są tak naprawdę tylko polami niejawnej klasy. Na przykład:

// foo.groovy 
final MYCONSTANT = "foobar" 
println MYCONSTANT 

class Helper { 
    def hello() { println MYCONSTANT } // won't work 
} 
new Helper().hello() 

jest mniej więcej odpowiednikiem:

class foo { 
    def run() { 
     final MYCONSTANT = "foobar" 
     println MYCONSTANT 
     new Helper().hello() 
    } 
    static main(args) { 
     new foo().run() 
    } 
} 

class Helper { 
    def hello() { println MYCONSTANT } // won't work 
} 

Łatwo zrozumieć, dlaczego to nie działa rozszerzył się. Łatwym zadaniem jest zadeklarowanie swoich "globaliów" w fikcyjnej klasie zwanej np. Stałe, a następnie po prostu wykonaj statyczny import. Działa nawet w jednym skrypcie. Przykład:

import static Constants.* 

class Constants { 
    static final MYCONSTANT = "foobar" 
} 

println MYCONSTANT 

class Helper { 
    def hello() { println MYCONSTANT } // works! 
} 
new Helper().hello() 

EDIT:

Również skrypty są trochę szczególny przypadek. Jeśli zadeklarujesz zmienną bez def lub dowolnych modyfikatorów, takich jak final, (to znaczy po prostu użyj jej), przejdzie ona w powiązanie ze skryptem. Więc w tym przypadku:

CONSTANT = "foobar" 
println "foobar" 

stałych jest w skrypcie całej wiążące, lecz w:

final CONSTANT = "foobar" 
println "foobar" 

stała jest zmienna lokalna w run() metody skryptu. Więcej informacji na ten temat można znaleźć na stronie https://web-beta.archive.org/web/20150108090004/http://groovy.codehaus.org/Scoping+and+the+Semantics+of+%22def%22

Answer 2

W Groovy 1.8+, można to osiągnąć za pomocą @Field annotation:

import groovy.transform.Field 

@Field final String MY_CONSTANT = 'constant' 

def printConstant() { println MY_CONSTANT } 

printConstant() 

Answer 3

The inny skuteczny sposób, aby dodać globalną aplikację stałe poziomie są zadeklarować jeden interfejs w odpowiednim opakowaniu, jak

interface applicationConstants { 
//All constants goes here. 
    static final float PI = 3.14 
    String ADMIN_USER = "ADMIN" 
    Map languages = [ 
     "en": "English", 
     "hi": "Hindi", 
     "mr": "Marathi" 

    ] 
// Like above you can declare all application level code constants here. 

} 

Zastosowanie stałych z dowolnej klasy, jak poniżej,

import packageNameContainingInterface.applicationConstants // import statement. 
def adminUser = applicationConstants.ADMIN_USER 
println adminUser