Pytanie idiomatycznego clojure o transformacji sekwencji

Question

Uczę się Clojure i potrzebuję popchnięcia we właściwym kierunku z tym problemem, który wymyśliłem.

Mam sekwencję zdarzeń. Każde wydarzenie zawiera "datę".

(def events 
    [ 
    [1509 :marry "Catherine of Aragon"] 
    [1527 :unmarry "Catherine of Aragon"] 
    [1533 :marry "Anne Boleyn"] 
    [1536 :unmarry "Anne Boleyn"] 
    [1536 :marry "Jane Seymour"] 
    [1537 :unmarry "Jane Seymour"] 
    [1540 :marry "Anne of Cleves"] 
    [1540 :unmarry "Anne of Cleves"] 
    [1540 :marry "Catherine Howard"] 
    [1542 :unmarry "Catherine Howard"] 
    [1543 :marry "Catherine Parr"]]) 

Chcę przekonwertować to na leniwą oś czasu, tj. Sekwencję zawierającą jeden wektor na rok. Począwszy od roku pierwszego wydarzenia i kontynuowania nieskończoności.

[[[:marry "Catherine of Aragon"]] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [] [[:unmarry "Catherine of Aragon"]] [] [] [] [] [] [[:marry "Ane Boleyn"]] [] [] [[:unmarry "Anne Boleyn"] [:marry "Jayne Seymour"]] ...] 

Answer 1

(def timeline 
    (let [events-by-year (group-by first events)] 
    (map #(map next (events-by-year %)) 
     (iterate inc (reduce min (keys events-by-year)))))) 

Szybki test:

=> (take 30 timeline) 
(((:marry "Catherine of Aragon"))()()()()()()()()()()()()()()()() 
() ((:unmarry "Catherine of Aragon"))()()()()() ((:marry "Anne Boleyn"))() 
() ((:unmarry "Anne Boleyn") (:marry "Jane Seymour")) ((:unmarry "Jane Seymour")) 
()) 

Answer 2

Proponuję coś takiego:

(defn timeline 
    ([] (timeline (ffirst *events*) *events*)) 
    ([time evts] 
    (let [[now later] (split-with #(= time (first %)) evts)] 
     (cons (map rest now) 
      (lazy-seq (timeline (inc time) later)))))) 

Test:

user> (take 30 (timeline)) 
(((:marry "Catherine of Aragon"))()()()()()()()()()()()()()()()()() 
((:unmarry "Catherine of Aragon"))()()()()() ((:marry "Anne Boleyn"))()() 
((:unmarry "Anne Boleyn") (:marry "Jane Seymour")) ((:unmarry "Jane Seymour"))()) 

jestem przy założeniu, że lista zdarzeń jest nieskończony, jak również :)

Zaktualizowany z usprawnieniami i zapożyczeniem kilku pomysłów z cgrand (dzięki :)