Racket: using wydarzenia w ramie okna%

Question

uczę Rakieta (dawniej PLT Scheme, dialekt LISP) i spróbować dowiedzieć się, jak obsługiwać zdarzenia inaczej niż paint-callback (może to nawet nie jeden).

Mam nadzieję, że wiele z this part of the doc, ale on-char i on-event wydaje się nie robić nic, co mogłoby mnie zainteresować (lub w ogóle nic).

Co więcej, nie rozumiem obszarów zdarzeń, kolejki-wywołania zwrotnego i ich zastosowań. Przykładem może być fajna rzecz! Będę wdzięczny miłemu człowiekowi, który mi napisze :).

Oto mój kod:

(define game (new frame%)) 

(define gameLay (class canvas% (super-new))) 

(new gameLay 
    [parent game] 
    [paint-callback (λ (canvas dc) #|draw things|#)]) 

chcę użyć czegoś w stylu „na kliknięcie myszą-left” (który nie istnieje) sposób używam „paint-zwrotnej”, ale myślę, trzeba dodać kroki (czytałem o obszarach zdarzeń itp.). wiem, że to nie działa, ale tutaj jest hipotetyczny kod Szukam:

(new gameLay 
    [parent game] 
    [paint-callback (λ (canvas dc) #|draw things|#)] 
    [on-mouse-click-left (λ (canvas dc) #|do other things|#)]) 

Answer 1

Oto mały program za pomocą płótna i zdarzeń klawiaturowych. Po naciśnięciu klawisza strzałki płótno pokazuje ostatnie naciśnięcie.

#lang racket/gui 

(define game-canvas% 
    (class canvas% 
    (inherit get-width get-height refresh) 

    ;; direction : one of #f, 'left, 'right, 'up, 'down 
    (define direction #f) 

    (define/override (on-char ke) 
     (case (send ke get-key-code) 
     [(left right up down) 
     (set! direction (send ke get-key-code)) 
     (refresh)] 
     [else (void)])) 

    (define/private (my-paint-callback self dc) 
     (let ([w (get-width)] 
      [h (get-height)]) 
     (when direction 
      (let ([dir-text (format "going ~a" direction)]) 
      (let-values ([(tw th _ta _td) 
          (send dc get-text-extent dir-text)]) 
       (send dc draw-text 
        dir-text 
        (max 0 (/ (- w tw) 2)) 
        (max 0 (/ (- h th) 2)))))))) 

    (super-new (paint-callback (lambda (c dc) (my-paint-callback c dc)))))) 

(define game-frame (new frame% (label "game") (width 600) (height 400))) 
(define game-canvas (new game-canvas% (parent game-frame))) 
(send game-frame show #t) 

Każda klatka ma przestrzeń zdarzeń, która zarządza wysyłaniem zdarzeń. Metoda on-char jest procedurą obsługi zdarzeń; jest uruchamiany w wątku procedury obsługi obszaru zdarzeń. Żadne dalsze zdarzenia nie zostaną przetworzone, dopóki nie zakończy się twoja metoda on-char. Jeśli chcesz zrobić coś skomplikowanego, możesz utworzyć oddzielny wątek i wykonać obliczenia. Jednym prostym sposobem na zrobienie tego jest utworzenie innej przestrzeni zdarzeń, która nie obsługuje zdarzeń dla żadnej ramki, ale która obsługuje "zdarzenia", które wysyłasz, używając queue-callback. Na przykład, należy wymienić definicji on-char powyżej to:

(define aux-eventspace (make-eventspace)) 

(define/override (on-char ke) 
    (parameterize ((current-eventspace aux-eventspace)) 
    (queue-callback 
    (lambda() 
     (case (send ke get-key-code) 
     ((left right up down) 
      (set! direction (send ke get-key-code)) 
      (refresh)) 
     (else (void))))))) 

Funkcja uwagę na queue-callback prowadzi się w oddzielnym wątku. Możesz wstawić niektóre wydruki, opóźnienia lub cokolwiek innego, aby przekonać się, że główna przestrzeń zdarzeń może nadal przetwarzać zdarzenia, podczas gdy druga obsługuje wywołania zwrotne.