Dlaczego program WINWORD.EXE nie kończy się po zamknięciu dokumentu z Delphi?

Question

Udało mi się wydestylować jeden z podstawowych problemów zakorzenionych w moim pytaniu How to trace _AddRef/_Release calls for OLE Automation objects w poniższej jednostce.

Odpowiem również na tę odpowiedź, na wypadek gdyby ktoś inny wpadł na to.

Pytanie: z poniższym kodem, dlaczego WINWORD.EXE nie zawsze kończy działanie (czasami kończy działanie).

Urządzenie prawdopodobnie zostanie przycięte jeszcze bardziej.

unit Unit2; 

interface 

uses 
    Winapi.Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, 
    Forms, Dialogs, StdCtrls, 
    WordXP; 

type 
    TForm2 = class(TForm) 
    WordXPFailsToQuitButton: TButton; 
    procedure WordXPFailsToQuitButtonClick(Sender: TObject); 
    private 
    FWordApplication: TWordApplication; 
    strict protected 
    function GetWordApplication: TWordApplication; virtual; 
    function GetWordApplication_Documents: Documents; virtual; 
    procedure WordApplication_DocumentBeforeClose(ASender: TObject; const Doc: _Document; var Cancel: WordBool); virtual; 
    procedure WordApplication_Quit(Sender: TObject); virtual; 
    property WordApplication: TWordApplication read GetWordApplication; 
    property WordApplication_Documents: Documents read GetWordApplication_Documents; 
    end; 

var 
    Form2: TForm2; 

implementation 

uses 
    Vcl.OleServer; 

{$R *.dfm} 

function TForm2.GetWordApplication: TWordApplication; 
begin 
    if not Assigned(FWordApplication) then 
    begin 
    FWordApplication := TWordApplication.Create(nil); 

    FWordApplication.AutoConnect := False; 
    FWordApplication.AutoQuit := False; 
    FWordApplication.ConnectKind := ckNewInstance; 
    FWordApplication.OnDocumentBeforeClose := WordApplication_DocumentBeforeClose; 
    FWordApplication.OnQuit := WordApplication_Quit; 
    FWordApplication.Connect; 
    end; 
    Result := FWordApplication; 
end; 

function TForm2.GetWordApplication_Documents: Documents; 
begin 
    Result := WordApplication.Documents; 
    if not Assigned(Result) then 
    raise EAccessViolation.Create('WordApplication.Documents'); 
end; 

procedure TForm2.WordXPFailsToQuitButtonClick(Sender: TObject); 
begin 
    try 
    WordApplication_Documents.Add(EmptyParam, EmptyParam, EmptyParam, EmptyParam); 
    WordApplication.Visible := True; 
    WordApplication.ActiveDocument.Close(False, EmptyParam, EmptyParam); 
    finally 
    WordApplication.OnQuit := nil; 
    WordApplication.OnDocumentBeforeClose := nil; 
    WordApplication.AutoQuit := True; 
    WordApplication.Disconnect; 
    WordApplication.Free; 
    FWordApplication := nil; 
    end; 
end; 

procedure TForm2.WordApplication_DocumentBeforeClose(ASender: TObject; const Doc: _Document; var Cancel: WordBool); 
begin 
    FWordApplication.Disconnect; 
end; 

procedure TForm2.WordApplication_Quit(Sender: TObject); 
begin 
    FWordApplication.Disconnect; 
end; 

end. 

Answer 1

Odpowiedź część 1:

zakomentuj rozłączeniem w poniższym przypadku:

procedure TForm2.WordApplication_DocumentBeforeClose(ASender: TObject; const Doc: _Document; var Cancel: WordBool); 
begin 
// FWordApplication.Disconnect; 
end; 

Impreza zostanie wywołana podczas metody DocumentClose (...), a następnie odłączyć i usunąć interfejs OLE z instancji FWordApplication.

Jeszcze nie zorientowałem się, który odnośnik jest zwisający, ale to skutecznie utrzymuje WINWORD.EXE przy życiu przez większość czasu.

Odpowiedź część 2:

Czasami WINWORD.EXE nie zamknąć, ponieważ wydarzenie toe WordApplication_DocumentBeforeClose nie nazywa. Powodem jest to, że kod działa tak szybko, że program Word nie jest jeszcze w pełni zainicjowany, aby wykonać zdarzenie.