Jak odtwarzać plik wave lub plik dźwiękowy za pomocą VBA

Question

Mam plik wave, który chcę odtwarzać za pomocą VBA. Pomóż mi utworzyć przycisk, który po kliknięciu odtwarza plik wave.

Answer 1

Oto sposób na pliki WAV. Umieścić ** **this code w zwykłym module kodu:

Option Explicit 
Public Declare Function sndPlaySound32 _ 
    Lib "winmm.dll" _ 
    Alias "sndPlaySoundA" (_ 
     ByVal lpszSoundName As String, _ 
     ByVal uFlags As Long) As Long 

Sub PlayTheSound(ByVal WhatSound As String) 
    If Dir(WhatSound, vbNormal) = "" Then 
     ' WhatSound is not a file. Get the file named by 
     ' WhatSound from the Windows\Media directory. 
     WhatSound = Environ("SystemRoot") & "\Media\" & WhatSound 
     If InStr(1, WhatSound, ".") = 0 Then 
      ' if WhatSound does not have a .wav extension, 
      ' add one. 
      WhatSound = WhatSound & ".wav" 
     End If 
     If Dir(WhatSound, vbNormal) = vbNullString Then 
      Beep   ' Can't find the file. Do a simple Beep. 
      Exit Sub 
     End If 
    Else 
     ' WhatSound is a file. Use it. 
    End If 

    sndPlaySound32 WhatSound, 0& ' Finally, play the sound. 
End Sub 

Teraz można odtwarzać dowolny plik wav za pośrednictwem innego makra wywołując że rutynowe powyżej i żywienia w każdym pliku znajdującego się w katalogu/media:

Sub PlayIt() 
    Select Case Range("A1").Value 
     Case "good" 
      PlayTheSound "chimes.wav" 
     Case "bad" 
      PlayTheSound "chord.wav" 
     Case "great" 
      PlayTheSound "tada.wav" 
    End Select 
End Sub 

Zabawa z tym.

Oto przykładowy plik gdzie mogę używać, aby radykalnie odsłonić losowe nazwy i zadań na dzień, to jest przypisane do przycisku, jak masz zamiar zrobić:

Random Task List with AUDIO Reveal