Wyzwalanie makro MS Word po zapisaniu zdarzenia

Question

Mój szablon MS Word 2007 ma stopkę z nazwą pliku w nim. Użytkownik otworzy szablon i wykona "Zapisz jako ...", aby zrobić swój dokument.

Chcę, aby nazwa pliku widoczna w stopce była natychmiast aktualizowana do nowej nazwy pliku.

Czy istnieje AfterSaveEvent lub coś, co mogę użyć jako haka, aby uruchomić mój skrypt VBA, który aktualizuje?

Czy jest o wiele łatwiejszy sposób?

Answer 1

Wystarczy utworzyć makro tak (wierzę, że działa lepiej, jeśli zawarte w Normal.dot)

Sub FileSaveAs() 
' 
' FileSaveAs Macro 
' Saves a copy of the document in a separate file 
' 
Dialogs(wdDialogFileSaveAs).Show 

'returns the name including the .doc extension 
ChosenFileNameAndExtension = ActiveDocument.Name 'Or use .FullName 

' Your code here 

End Sub 

To będzie wyzwalany gdy użytkownik wybierze opcję „Zapisz plik jako”

HTH!

Answer 2

To działało na podstawie odpowiedzi @belisarius':

Sub UpdateAll() 
    Dim oStory As Object 
    Dim oToc As Object 

    'Exit if no document is open 
    If Documents.Count = 0 Then Exit Sub 
    Application.ScreenUpdating = False 

    For Each oStory In ActiveDocument.StoryRanges 
     oStory.Fields.Update 'Update fields in all stories 
    Next oStory 

    For Each oToc In ActiveDocument.TablesOfContents 
     oToc.Update 'Update table of contents 
    Next oToc 

    Application.ScreenUpdating = True 
End Sub 

Sub FileSaveAs() 
' 
' FileSaveAs Macro 
' Saves a copy of the document in a separate file 
' 
Dialogs(wdDialogFileSaveAs).Show 

UpdateAll 


End Sub 

Answer 3

Wiemy, że zdarzenie Aftersave nie jest dostępna dla programu Microsoft Word. Ale program Word pozwala nam używać zdarzenia BeforeSave. Zaimplementowałem to rozwiązanie i działa dobrze.

Najpierw musimy wdrożyć Application.onTime metody w programie Word BeforeSave przypadku następująco

Private Sub mobjWord_DocumentBeforeSave(ByVal Doc As Word.Document, SaveAsUI As Boolean, Cancel As Boolean) 
    Word.Application.OnTime Now + TimeValue("00:00:02"), "AfterSave" 
End Sub 

Metoda ta będzie wywoływać metodę zwaną AfterSave po 2 sekundach.

Public Sub AfterSave() 
    While Word.ActiveDocument.Application.BackgroundSavingStatus <> 0 
     DoEvents 
    Wend 
'Implement your code here 
End Sub 

W tej metodzie pętla while będzie krążyć, dopóki proces zapisywania dokumentu nie zostanie zakończony. Możesz więc zaimplementować kod po pętli while.