Replikowanie wiersza polecenia przy plikach wsadowych

Question

Próbuję zreplikować wiersz polecenia za pomocą plików wsadowych. Mój obecny kod jest odtworzony poniżej.

@echo off 
title Command Prompt 
:LOOP 
set /p COMMAND="%CD%>" 
title Command Prompt - %COMMAND% 
call %COMMAND% 
echo. 
title Command Prompt 
goto LOOP 

Jednak mam jeden problem. Jeśli wywołuję program (taki jak gpedit.msc), plik wsadowy czeka, aż program wróci przed kontynuowaniem, gdy normalny wiersz polecenia powróci bez oczekiwania na powrót programu.

Jak sprawdzić, czy polecenie jest programem, więc mogę użyć polecenia start?

Answer 1

Możesz wyszukać plik wykonywalny dla user32.dll.

@echo off 
title Command Prompt 
:LOOP 
    set /p COMMAND="%CD%>" 
    title Command Prompt - %COMMAND% 

    call :is_gui %COMMAND% 
    if errorlevel 1 (
     call %COMMAND% 
    ) else (
     start "" %COMMAND% 
    ) 

    echo. 
    title Command Prompt 
    goto LOOP 

:is_gui app_name 
    set app_name=%~1 
    set file_app= 

    rem Get path of application 
    if exist "%app_name%" (
     set file_app=%app_name% 
    ) else (
     rem Lookup path of app 
     for %%P in (%PATHEXT%) do (
      for %%I in (%1 %1%%P) do (
      if exist "%%~$PATH:I" (
       set file_app=%%~$PATH:I 
       goto continue 
      ) 
     ) 
     ) 
    ) 
    :continue 
    if "%file_app%"=="" exit /b 1 
    find /i "user32.dll" < "%file_app%" >nul 2>&1 
    exit /b %errorlevel%