Jak korzystać z jsonbuilder z kolekcjami?

Question

muszę utworzyć wiadomość json tak:

{ 
    success:true, 
    count:3, 
    data: [ 
    {id:1}, 
    {id:2}, 
    {id:3} 
    ] 
} 

Próbowałem to

import groovy.json.* 

def tasks = [1, 2,3] 
def json = new JsonBuilder() 

json{ 
    success(true) 
    count(tasks.size()) 
    data { 
    tasks.each { 
     data(
     id: it   
    ) 
    } 
    } 
} 

JsonOutput.prettyPrint(json.toString()) 

ale to nie działa. Czy ktoś może mi pokazać, jak to działa?

Answer 1

Polecam przekształcając listę zadań do listy postaci [[id: 1], [id: 2], [id: 3]], a następnie „jsonizing” go:

import groovy.json.JsonBuilder 

def tasks = [1, 2, 3] 
def json = new JsonBuilder() 

json{ 
    success(true) 
    count(tasks.size()) 
    data(tasks.collect {[id: it]}) 
} 

println json.toPrettyString() 

I zazwyczaj wolą generowania struktur danych w Groovy pierwszy (np listy, mapy) i następnie konwertuj je do JSON, w ten sposób zwykle mam większą kontrolę nad danymi, które będą serializowane i nie muszę dołączać logiki do kodu serializacji.

import groovy.json.JsonBuilder 

def tasks = [1, 2, 3] 

def data = [ 
    success: true, 
    count: tasks.size(), 
    data: tasks.collect {[id: it]} 
] 

def json = new JsonBuilder(data) 
println json.toPrettyString()