Jak uzyskać wykres radialny (polarny) za pomocą wykresu gnu? .

Question

Chcę promieniowe (polarny) Działka przy użyciu gnuplot (czyli w kołowym układzie współrzędnych (r, theta)

Tutaj użyłem wartości:

Theta Max-strain 
0  3400 
60 5300 
120 4700 
180 3800 
240 4100 
300 3100 
360 3400 

Jak zdobyć taką działkę ? użyciu gnu-plot

Answer 1

próbowałem odtworzyć fabułę swoje pytanie, a to jest to, co wymyśliłem:

unset border 
set polar 
set angles degrees #set gnuplot on degrees instead of radians 

set style line 10 lt 1 lc 0 lw 0.3 #redefine a new line style for the grid 

set grid polar 60 #set the grid to be displayed every 60 degrees 
set grid ls 10 

set xrange [-6000:6000] #make gnuplot to go until 6000 
set yrange [-6000:6000] 

set xtics axis #disply the xtics on the axis instead of on the border 
set ytics axis 

set xtics scale 0 #"remove" the tics so that only the y tics are displayed 
set xtics ("" 1000, "" 2000, "" 3000, "" 4000, "" 5000, "" 6000) #set the xtics only go from 0 to 6000 with increment of1000 but do not display anything. This has to be done otherwise the grid will not be displayed correctly. 
set ytics 0, 1000, 6000 #make the ytics go from the center (0) to 6000 with incrment of 1000 

set size square 

set key lmargin 

set_label(x, text) = sprintf("set label '%s' at (6500*cos(%f)), (6500*sin(%f))  center", text, x, x) #this places a label on the outside 

#here all labels are created 
eval set_label(0, "0") 
eval set_label(60, "60") 
eval set_label(120, "120") 
eval set_label(180, "180") 
eval set_label(240, "240") 
eval set_label(300, "300") 


set style line 11 lt 1 lw 2 pt 2 ps 2 #set the line style for the plot 

#and finally the plot 
plot "-" u 1:2 t "Max strain" w lp ls 11 
0 3400 
60 5300 
120 4700 
180 3800 
240 4100 
300 3100 
360 3400 
e 

Jak widać , główną różnicą jest to, że kąt 0 nie jest na górze, ale po prawej (co jest matematycznie poprawne). Możesz to zmienić, modyfikując użycie opóźnienia na wykresie i funkcji set_label.

Jak widać w scenariuszu, nie wszystko jest naprawdę ostre i błyszczące. Jeśli ktoś znajdzie ulepszenia, daj mi znać!

Ostatnia część "porady": nie zawsze rozsądne jest odtwarzanie wykresu z jakiegoś narzędzia z gnuplotem. Często siła gnuplot polega na wykreślaniu danych w najprostszy sposób, aby być łatwo powtarzalnym. Może uda ci się wykopać niektóre linijki z powyższego scenariusza i nadal będziesz z niego zadowolony.

Answer 2

Oto podręcznik http://t16web.lanl.gov/Kawano/gnuplot/polar-e.html

set polar 
set angles degrees 

i zdobyć koła:

set grid polar 

Oto demo: http://gnuplot.sourceforge.net/demo/polar.html