SQL do tworzenia użytkowników .Net Membership Provider

Question

Mam skrypt SQL, który tworzy użytkowników w mojej bazie danych. Korzysta z zapisanych procesów członkostwa .Net.

W tym momencie działa dobrze.

Jedynym problemem jest to, że hasła są zapisane jako czysty tekst. Co należy zmienić, żeby one solone/zaszyfrowany (nie wiem, co by tu użyć termin)

GO 

DECLARE @return_value int, 
    @UserId uniqueidentifier 


EXEC @return_value = [dbo].[aspnet_Membership_CreateUser] 
    @ApplicationName = N'Theater', 
    @UserName = N'sam.sosa', 
    @Password = N'mypassword', 
    @PasswordSalt = N'eyhKDP858wdrYHbBmFoQ6DXzFE1FB+RDP4ULrpoZXt6f', 
    @Email = N'sam@Simple.com', 
    @PasswordQuestion = N'Whats your favorite color', 
    @PasswordAnswer = N'Fusia', 
    @IsApproved = 1, 
    @CurrentTimeUtc = '2010-03-03', 
    @CreateDate = '2010-03-03', 
    @UniqueEmail = 1, 
    @PasswordFormat = 0, 
    @UserId = @UserId OUTPUT 

SELECT @UserId as N'@UserId' 

SELECT 'Return Value' = @return_value 

GO 

dzięki!

Answer 1

Pod maską to wygląda na „mieszany” tryb pamięci hasło, to po prostu oblicza:

SHA1 (Salt + hasło)

sól jest przechowywany Base64 zakodowane, więc musi być dekodowane przed do połączenia z hasłem (Unicode). Ostatecznie wynikiem jest kodowanie Base64 do przechowywania.

Następujący (straszny) SQL wypisze odpowiednio zakodowaną wartość, którą można zastąpić zamiast "mypassword", które obecnie posiadasz. Musisz również ustawić @PasswordFormat na 1, aby wskazać, że hasło jest przechowywane w haszowaniu.

declare @salt nvarchar(128) 
declare @password varbinary(256) 
declare @input varbinary(512) 
declare @hash varchar(64) 

-- Change these values (@salt should be Base64 encoded) 
set @salt = N'eyhKDP858wdrYHbBmFoQ6DXzFE1FB+RDP4ULrpoZXt6f' 
set @password = convert(varbinary(256),N'mypassword') 

set @input = hashbytes('sha1',cast('' as xml).value('xs:base64Binary(sql:variable(''@salt''))','varbinary(256)') + @password) 
set @hash = cast('' as xml).value('xs:base64Binary(xs:hexBinary(sql:variable(''@input'')))','varchar(64)') 

-- @hash now contains a suitable password hash 
-- Now create the user using the value of @salt as the salt, and the value of @hash as the password (with the @PasswordFormat set to 1) 

DECLARE @return_value int, 
    @UserId uniqueidentifier 

EXEC @return_value = [dbo].[aspnet_Membership_CreateUser] 
    @ApplicationName = N'Theater', 
    @UserName = N'sam.sosa', 
    @Password = @hash, 
    @PasswordSalt = @salt, 
    @Email = N'sam@Simple.com', 
    @PasswordQuestion = N'Whats your favorite color', 
    @PasswordAnswer = N'Fusia', 
    @IsApproved = 1, 
    @CurrentTimeUtc = '2010-03-03', 
    @CreateDate = '2010-03-03', 
    @UniqueEmail = 1, 
    @PasswordFormat = 1, 
    @UserId = @UserId OUTPUT 

SELECT @UserId as N'@UserId' 

SELECT 'Return Value' = @return_value