Uzyskaj wszystkie pliki źródłowe, których cel zależy od CMake

Question

Z CMake, w jaki sposób mogę uzyskać listę wszystkich plików źródłowych, które trafiają do wykonywalnych celów, w tym wszystkie źródła we wszystkich celach, od których ten plik wykonywalny jest zależny?

Mamy wzorzec w bazie kodu, w którym wywołujący inicjatory są generowani przez system kompilacji na podstawie nazw plików i ścieżek w drzewie źródłowym. Potrzebuję więc pełnej ścieżki (lub źródła względem root) do wszystkich plików źródłowych, od których zależy wykonywany cel.

Answer 1

Oto mój kawałek kodu, aby uzyskać link zależności jeden cel to:

function(target_link_libraries _target) 
    set(_mode "PUBLIC") 
    foreach(_arg IN LISTS ARGN) 
     if (_arg MATCHES "INTERFACE|PUBLIC|PRIVATE|LINK_PRIVATE|LINK_PUBLIC|LINK_INTERFACE_LIBRARIES") 
      set(_mode "${_arg}") 
     else() 
      if (NOT _arg MATCHES "debug|optimized|general") 
       set_property(GLOBAL APPEND PROPERTY GlobalTargetDepends${_target} ${_arg}) 
      endif() 
     endif() 
    endforeach() 
    _target_link_libraries(${_target} ${ARGN}) 
endfunction() 

function(get_link_dependencies _target _listvar) 
    set(_worklist ${${_listvar}}) 
    if (TARGET ${_target}) 
     list(APPEND _worklist ${_target}) 
     get_property(_dependencies GLOBAL PROPERTY GlobalTargetDepends${_target}) 
     foreach(_dependency IN LISTS _dependencies) 
      if (NOT _dependency IN_LIST _worklist) 
       get_link_dependencies(${_dependency} _worklist) 
      endif() 
     endforeach() 
     set(${_listvar} "${_worklist}" PARENT_SCOPE) 
    endif() 
endfunction() 

Dla starszych wersjach CUpewnij (przed 3.4), trzeba będzie wymienić czek IN_LIST z list(FIND ...) rozmowy:

[...] 
     list(FIND _worklist ${_dependency} _idx) 
     if (${_idx} EQUAL -1) 
      get_link_dependencies(${_dependency} _worklist) 
     endif() 
[...] 

A oto kod testu użyłem:

cmake_minimum_required(VERSION 3.4) 

project(GetSources) 

cmake_policy(SET CMP0057 NEW) 

[... include functions posted above ...] 

file(WRITE a.cc "") 
add_library(A STATIC a.cc) 

file(WRITE b.cc "") 
add_library(B STATIC b.cc) 

file(WRITE main.cc "int main() { return 0; }") 
add_executable(${PROJECT_NAME} main.cc) 

target_link_libraries(B A) 
target_link_libraries(${PROJECT_NAME} B) 

get_link_dependencies(${PROJECT_NAME} _deps) 
foreach(_dep IN LISTS _deps) 
    get_target_property(_srcs ${_dep} SOURCES) 
    get_target_property(_src_dir ${_dep} SOURCE_DIR) 
    foreach(_src IN LISTS _srcs) 
     message("${_src_dir}/${_src}") 
    endforeach() 
endforeach() 

Referencje

• Recursive list of LINK_LIBRARIES in CMake