Jak mogę sprawdzić rozszerzenie pliku za pomocą Perla?

Question

Do mojego skryptu perl plik jest przekazywany jako argument. Plik może być plikiem .txt lub plikiem .zip zawierającym plik .txt.

Chcę napisać kod, który wygląda mniej więcej tak

if ($file is a zip) { 

    unzip $file 
    $file =~ s/zip$/txt/; 
} 

Jeden ze sposobów sprawdzenia rozszerzenie jest zrobić podział na . a następnie dopasować ostatni wynik w tablicy (zwrócony przez split).

Czy jest jakiś lepszy sposób?

Answer 1

Możesz użyć File :: Basename do tego.

#!/usr/bin/perl 

use 5.010; 
use strict; 
use warnings; 

use File::Basename; 

my @exts = qw(.txt .zip); 

while (my $file = <DATA>) { 
    chomp $file; 
    my ($name, $dir, $ext) = fileparse($file, @exts); 

    given ($ext) { 
    when ('.txt') { 
     say "$file is a text file"; 
    } 
    when ('.zip') { 
     say "$file is a zip file"; 
    } 
    default { 
     say "$file is an unknown file type"; 
    } 
    } 
} 

__DATA__ 
file.txt 
file.zip 
file.pl 

Running to daje:

$ ./files 
file.txt is a text file 
file.zip is a zip file 
file.pl is an unknown file type 

Answer 2

Co powiesz na sprawdzenie końca nazwy pliku?

if ($file =~ /\.zip$/i) { 

, a następnie:

use strict; 
use Archive::Extract; 

if ($file =~ /\.zip$/i) { 
    my $ae = Archive::Extract->new(archive => $file); 
    my $ok = $ae->extract(); 
    my $files = $ae->files(); 
} 

więcej informacji here.

Answer 3

Można sprawdzić rozszerzenia pliku przy użyciu regex mecz jak:

if($file =~ /\.zip$/i) { 
     # $file is a zip file 
} 

Answer 4

Dlaczego polegać na rozszerzenie pliku? Wystarczy spróbować rozpakować i używać odpowiednią obsługę wyjątków:

eval { 
    # try to unzip the file 
}; 

if ($@) { 
    # not a zip file 
} 

Answer 5

Innym rozwiązaniem jest wykorzystanie File::Type który określa typ pliku binarnego.

use strict; 
use warnings; 

use File::Type; 

my $file  = '/path/to/file.ext'; 
my $ft  = File::Type->new(); 
my $file_type = $ft->mime_type($file); 

if ($file_type eq 'application/octet-stream') { 
    # possibly a text file 
} 
elsif ($file_type eq 'application/zip') { 
    # file is a zip archive 
} 

W ten sposób nie musisz radzić sobie z brakującymi/błędnymi rozszerzeniami.

Answer 6

Wiem, że to pytanie jest kilka lat, ale dla każdego, kto przychodzi tu w przyszłości, łatwym sposobem rozpadają ścieżkę pliku do jego składowej ścieżki nazwa pliku, nazwa serwisu i rozszerzenie są następujące.

use File::Basename; 

my $filepath = '/foo/bar.txt'; 

my ($basename, $parentdir, $extension) = fileparse($filepath, qr/\.[^.]*$/); 
my $filename = $basename . $extension; 

Możesz przetestować jego wyniki, wykonując następujące czynności.

my @test_paths = (
    '/foo/bar/fish.wibble', 
    '/foo/bar/fish.', 
    '/foo/bar/fish.asdf.d', 
    '/foo/bar/fish.wibble.', 
    '/fish.wibble', 
    'fish.wibble', 
); 

foreach my $this_path (@test_paths) { 
    print "Current path: $this_path\n"; 
    my ($this_basename, $parentdir, $extension) = fileparse($this_path, qr/\.[^.]*$/); 
    my $this_filename = $this_basename . $extension; 

    foreach my $var (qw/$parentdir $this_filename $this_basename $extension/) { 
     print "$var = '" . eval($var) . "'\n"; 
    } 

    print "\n\n"; 
} 

Mam nadzieję, że to pomoże.