Wyliczyć kolejność w Clojure?

Question

W Pythonie mogę to zrobić:

animals = ['dog', 'cat', 'bird'] 
for i, animal in enumerate(animals): 
    print i, animal 

które wyjścia:

0 dog 
1 cat 
2 bird 

Jak chciałbym osiągnąć to samo w Clojure? Uważałem podstawie listy ze zrozumieniem tak:

(println 
    (let [animals ["dog" "cat" "bird"]] 
    (for [i (range (count animals)) 
      animal animals] 
     (format "%d %d\n" i animal)))) 

Ale to wypisuje każdą kombinację liczby i zwierzęcia. Zgaduję, że jest prosty i elegancki sposób, ale nie widzę tego.

Answer 1

Jest map-indexed w rdzeniu, co stanowi 1,2.

Twój przykład byłoby:

(doseq [[i animal] (map-indexed vector ["dog" "cat" "bird"])] 
    (println i animal)) 

Answer 2

Szybkie rozwiązanie:

(let [animals ["dog", "cat", "bird"]] 
    (map vector (range) animals)) 

Albo, jeśli chcesz zawinąć go w funkcję:

(defn enum [s] 
    (map vector (range) s)) 

(doseq [[i animal] (enum ["dog", "cat", "bird"])] 
    (println i animal)) 

Co się dzieje tutaj jest wektorem funkcja jest stosowana do każdego elementu w obu sekwencjach, a wynik jest zbierany w leniwym zbiorze.

Dalej, spróbuj w repl.

Answer 3

Zastosowanie indeksowane od clojure.contrib.seq:

Zastosowanie: (indexed s) Zwraca leniwy sekwencja [indeks, poz] parach, gdzie przedmioty pochodzą z „s” i indeksy liczą się od zera.

(indexed '(a b c d)) => ([0 a] [1 b] [2 c] [3 d]

Dla przykładu to

(require 'clojure.contrib.seq) 
(doseq [[i animal] (clojure.contrib.seq/indexed ["dog", "cat", "bird"])] 
    (println i animal)) 

Answer 4

map-indexed wygląda w porządku, ale: Czy naprawdę potrzebujemy wszystkich rzeczy doseq i dekonstrukcji args w innych odpowiedzi?

(map-indexed println ["dog", "cat", "bird"]) 

EDIT: jak zauważył @gits to działa w REPL ale nie szanuję clojure jest leniwy domyślnie. dorun wydaje się być najbliższym among doseq, doall and doseq dla tego. doseq, jakkolwiek, wydaje się być idiomatycznym faworytem tutaj.

(dorun (map-indexed println ["dog", "cat", "bird"])) 

Answer 5

Jeszcze innym rozwiązaniem jest stosowanie reduce-kv, które pary elementów, z zastosowaniem wektora z ich pozycjach.

Zatem

(reduce-kv #(println %2 %3) nil ["dog" "cat" "bird"]) 

lub być może nieco bardziej wyraźne

(reduce-kv (fn [_ i animal] (println i animal)) nil ["dog" "cat" "bird"]) 

Nie chciałbym wybrać to rozwiązanie w stosunku do jednego z doseq tutaj, ale dobrze jest mieć świadomość tej specjalizacji dla wektorów w reduce-kv.