Jak serializować zamknięcie w Perlu?

Question

myślę, że to może być najlepiej na przykładzie zapytał:

use strict; 
use warnings; 
use 5.010; 
use Storable qw(nstore retrieve); 

local $Storable::Deparse = 1; 
local $Storable::Eval = 1; 

sub sub_generator { 
    my ($x) = @_; 

    return sub { 
     my ($y) = @_; 
     return $x + $y; 
    }; 
} 

my $sub = sub_generator(1000); 
say $sub->(1); # gives 1001 
nstore($sub, "/tmp/sub.store"); 
$sub = retrieve("/tmp/sub.store"); 
say $sub->(1); # gives 1 

Kiedy zrzucić /tmp/sub.store widzę:

$VAR1 = sub { 
      package Storable; 
      use warnings; 
      use strict 'refs'; 
      my($y) = @_; 
      return $x + $y; 
     } 

Ale $x nigdy nie jest zdefiniowana w tym sub. Spodziewam się, że sub wygenerowany przez sub_generator będzie miał zastąpioną $x swoją rzeczywistą wartością podczas generowania. Jak mam to rozwiązać?

Uwaga: to pytanie dotyczy tego one.

Answer 1

Niestety nie sądzę, że Storable współpracuje z zamknięciami. Istnieją jednak inne moduły CPAN, które będą serializować zamknięcie. Na przykład Data::Dump::Streamer

use 5.012; 
use warnings; 
use Data::Dump::Streamer; 

sub sub_generator { 
    my ($x) = @_; 

    return sub { 
     my ($y) = @_; 
     return $x + $y; 
    }; 
} 

my $sub = sub_generator(1000); 
say $sub->(1); # gives 1001 

my $serialised = Dump($sub)->Out; 
my $copy = do { 
    my $CODE1 = undef; 
    eval $serialised; 
    $CODE1; 
}; 

say $copy->(2); # gives 1002 
say $sub->(1); # still gives 1001 

To właśnie kod odcinkach wygląda po wydrukowaniu tutaj, say Dump $sub;:

my ($x); 
$x = 1000; 
$CODE1 = sub { 
      use warnings; 
      use strict 'refs'; 
      BEGIN { 
      $^H{'feature_unicode'} = q(1); 
      $^H{'feature_say'} = q(1); 
      $^H{'feature_state'} = q(1); 
      $^H{'feature_switch'} = q(1); 
      } 
      my($y) = @_; 
      return $x + $y; 
     }; 

Aktualizacja

Zobacz wątek Storable and Closures na perl5 portierzy listy. Potwierdza to, co myślałem o Storable i zamknięciach.

/I3az/