Jak sprawdzić, czy moja aplikacja konsoli Delphi jest przekierowywana do pliku lub potoku?

Question

Mam app konsoli, który musi włączyć lub wyłączyć niektóre operacje, gdy wyjście jest przekierowywane (zewnętrznie) do pliku lub rury (MojaAplik.exe> ​​foo.bar)

Jak mogę sprawdzić, czy moja aplikacja konsoli Delphi jest przekierowywany do pliku lub rury?

Answer 1

można korzystać z funkcji GetStdHandle i GetFileType.

najpierw pobrać uchwyt wyjścia konsoli przy użyciu funkcji GetStdHandle i wtedy można sprawdzić rodzaj uchwytu z funkcją GetFileType.

{$APPTYPE CONSOLE} 

{$R *.res} 

uses 
    Windows, 
    SysUtils; 


function ConsoleRedirected: Boolean; 
var 
    FileType : DWORD; 
begin 
    FileType:= GetFileType(GetStdHandle(STD_OUTPUT_HANDLE)); 
    Result := (FileType=FILE_TYPE_PIPE) or (FileType=FILE_TYPE_DISK); 
end; 


begin 
    try 
    if ConsoleRedirected then 
     Writeln('Hello From File') 
    else 
     Writeln('Hello Console'); 
    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
end. 

Answer 2

Podejście, które tu prezentuję, wydaje się być hacky, ale nie mogę znaleźć lepszego sposobu na wykrycie, czy standardowe wyjście zostało przekierowane z konsoli ekranowej. Podejście z użyciem GetFileType nie może wykryć wszystkich form przekierowania, ponieważ niektóre przekierowania dotyczą urządzeń typu FILE_TYPE_CHAR.

---

połączeń GetConsoleMode() przechodząc standardowego uchwytu wyjściowego. Jeśli zawiedzie GetConsoleMode(), Twoja konsola została przekierowana.

program RedirectionDetection; 
{$APPTYPE CONSOLE} 
uses 
  Windows; 

function ConsoleRedirected: Boolean; 
var 
  Mode: DWORD; 
begin 
    Result := not GetConsoleMode(GetStdHandle(STD_OUTPUT_HANDLE), Mode); 
end; 

begin 
  if ConsoleRedirected then begin 
    Writeln('I have been redirected'); 
  end else begin 
    Writeln('I am a console'); 
    Readln; 
  end; 
end.