Usuwanie liczb z ciągu

Question

Chciałbym wiedzieć, jak mogę usunąć numery z ciągu. Próbuję użyć StringReplace i nie wiem jak powiedzieć funkcję, którą chcę zastąpić liczbami.

Oto, co starałem:

StringReplace(mString, [0..9], '', [rfReplaceAll, rfIgnoreCase]); 

Answer 1

Proste, ale skuteczne. Może być zoptymalizowany, ale powinien dać Ci to, czego potrzebujesz na początek:

function RemoveNumbers(const aString: string): string; 
var 
    C: Char; 
begin 
    Result := ''; 
    for C in aString do begin 
     if not CharInSet(C, ['0'..'9']) then 
     begin 
     Result := Result + C; 
     end; 
    end; 
end; 

Answer 2

StringReplace nie akceptuje ustawiony jako drugi argument. Może ktoś będzie miał bardziej odpowiednie podejście, ale to działa:

StringReplace(mString, '0', '', [rfReplaceAll, rfIgnoreCase]); 
StringReplace(mString, '1', '', [rfReplaceAll, rfIgnoreCase]);  
StringReplace(mString, '2', '', [rfReplaceAll, rfIgnoreCase]); 

itp

Answer 3

Dobrze byłem zmęczony szuka już budować funkcje więc już tworzyć własne:

function RemoveNumbers(const AValue: string): string; 
    var 
     iCar : Integer; 
     mBuffer : string; 
    begin 
     mBuffer := AValue; 

     for iCar := Length(mBuffer) downto 1 do 
     begin 
     if (mBuffer[iCar] in ['0'..'9']) then 
      Delete(mBuffer,iCar,1); 
     end; 
     Result := mBuffer; 
    end; 

Answer 4

Dość szybka wersja lokalna.

procedure RemoveDigits(var s: string); 
var 
    i, j: Integer; 
    pc: PChar; 
begin 
    j := 0; 
    pc := PChar(@s[1]); 
    for i := 0 to Length(s) - 1 do 
    if pc[i] in ['0'..'9'] then 
       //if CharInSet(pc[i], ['0'..'9']) for Unicode version 
     Inc(j) 
    else 
     pc[i - j] := pc[i]; 
    SetLength(s, Length(s) - j); 
end; 

Answer 5

Ma to samo wyjście co wersja Nicka, ale jest to ponad 3-krotnie szybsze z krótkimi łańcuchami. Im dłuższy tekst, tym większa różnica.

function RemoveNumbers2(const aString: string): string; 
var 
    C:Char; Index:Integer; 
begin 
    Result := ''; 
    SetLength(Result, Length(aString)); 
    Index := 1; 
    for C in aString do 
    if not CharInSet(C, ['0' .. '9']) then 
    begin 
     Result[Index] := C; 
     Inc(Index); 
    end; 
    SetLength(Result, Index-1); 
end; 

Nie marnuj cennych cykli procesora, jeśli nie musisz.

Answer 6

użycie tego

function RemoveNonAlpha(srcStr : string) : string; 
const 
CHARS = ['0'..'9']; 
var i : integer; 
begin 
result:=''; 
for i:=0 to length(srcStr) do 
if (srcstr[i] in CHARS) then 
result:=result+srcStr[i]; 
end ; 

można nazwać jak ten

edit2.text: = RemoveNonAlpha (edit1.text);