W Perlu, w jaki sposób mogę znaleźć indeks danej wartości w tablicy?

Question

$VAR1 = [ 
      '830974', 
      '722065', 
      '722046', 
      '716963' 
     ]; 

Jak mogę obliczyć indeks tablicy dla wartości „722065”?

Answer 1

firstidx funkcja z List::MoreUtils może pomóc:

use strict; 
use warnings; 
use List::MoreUtils qw(firstidx); 

my @nums = ('830974', '722065', '722046', '716963'); 
printf "item with index %i in list is 722065\n", firstidx { $_ eq '722065' } @nums; 

__END__ 

 
item with index 1 in list is 722065 

Answer 2

Tutaj się pośpiesznie napisane próbę odwrotny look-up przy użyciu skrótu.

my $VAR1 = [ '830974', '722065', '722046', '716963' ]; 

my %reverse; 
$reverse{$VAR1->[$_]} = $_ for 0 .. @$VAR1 - 1; 

print $reverse{722065}; 

Nie uwzględnia to tablic z duplikatami wartości. Nie popieram tego rozwiązania dla kodu produkcyjnego.

Answer 3

Zapoznaj się dyskusja na perlmonks: http://www.perlmonks.org/?node_id=66003

Answer 4

Zapoznaj się z Perl FAQ

Answer 5

Oto w jaki sposób można znaleźć wszystkie pozycje, w których pojawia się dana wartość:

#!/usr/bin/perl 

use strict; 
use warnings; 

my @x = (1, 2, 3, 3, 2, 1, 1, 2, 3, 3, 2, 1); 
my @i = grep { $x[$_] == 3 } 0 .. $#x; 
print "@i\n"; 

Jeśli potrzebne jest tylko pierwszy indeks, należy użyć List::MoreUtils::first_index.

Answer 6

to jest w porządku, każdy był nowy w perl w jednym punkcie

$ a jest elementem wydrukować indeks w @list ...

my @list = (124124, 323, 156666, 124412, 3333, 4444444444, 124124124, 24412); 
my $a = 4444444444; 

print 
substr($_=($,= 
chr($==39)).(
join$,,@list).$,,$=-$=, 
index$_,$,.$a.$,)=~ 
tr/'//+$=---$=; 

Answer 7

Jeśli tylko trzeba spojrzeć w górę jeden przedmiot, użyj firstidx, jak powiedzieli inni.

Jeśli trzeba zrobić wiele wyszukiwań, budowania indeksu.

Jeśli elementy tablicy są wyjątkowe, budowania indeksu jest dość prosta. Ale nie jest trudniej zbudować taki, który obsługuje duplikaty przedmiotów. Przykłady zarówno wykonaj:

use strict; 
use warnings; 

use Data::Dumper; 

# Index an array with unique elements. 
my @var_uniq = qw(830974 722065 722046 716963); 
my %index_uniq = map { $var_uniq[$_] => $_ } 0..$#var_uniq; 

# You could use hash slice assinment instead of map: 
# my %index_uniq; 
# @index_uniq{ @var_uniq } = 0..$#var_uniq 

my $uniq_index_of_722065 = $index_uniq{722065}; 
print "Uniq 72665 at: $uniq_index_of_722065\n"; 
print Dumper \%index_uniq; 

# Index an array with repeated elements. 
my @var_dupes = qw(830974 722065 830974 830974 722046 716963 722065); 
my %index_dupes; 
for(0..$#var_dupes) { 
    my $item = $var_dupes[$_]; 

    # have item in index? 
    if($index_dupes{$item}) { 
     # Add to array of indexes 
     push @{$index_dupes{$item}}, $_; 
    } 
    else { 
     # Add array ref with index to hash. 
     $index_dupes{$item} = [$_]; 
    } 
} 

# Dereference array ref for assignment: 
my @dupe_indexes_of_722065 = @{ $index_dupes{722065} }; 

print "Dupes 722065 at: @dupe_indexes_of_722065\n"; 
print Dumper \%index_dupes; 

Answer 8

użyciu List::Util, który jest moduł podstawowy, w przeciwieństwie List::MoreUtils, który nie jest:

use List::Util qw(first); 

my @nums = ('830974', '722065', '722046', '716963'); 
my $index = first { $nums[$_] eq '722065' } 0..$#nums; 

Answer 9

use strict; 
use Data::Dumper; 

sub invert 
{ 
my $i=0; 
map { $i++ => $_ } @_; 
} 

my @a = ('a','b','c','d','e'); 

print Dumper @a; 

print Dumper invert @a;