Pary jako klucze mieszające

Question

Czy ktoś wie, jak utworzyć skrót z parami łańcuchów służących jako klucze w perlu?

Coś ...

{ 
    ($key1, $key2) => $value1; 
    ($key1, $key3) => $value2; 
    ($key2, $key3) => $value3; 

itp ....

Answer 1

Nie można mieć parę skalarów jako klawisz skrótu, ale można zrobić wielopoziomowym hash:

my %hash; 
$hash{$key1}{$key2} = $value1; 
$hash{$key1}{$key3} = $value2; 
$hash{$key2}{$key3} = $value3; 

Jeśli chcesz zdefiniować to wszystko naraz:

my %hash = ($key1 => { $key2 => $value1, $key3 => $value2 }, 
      $key2 => { $key3 => $value3 }); 

Alternatywnie, jeśli działa w danej sytuacji, można po prostu złączyć swój klucz y razem

$hash{$key1 . $key2} = $value1; # etc 

Albo dodać separator do oddzielania kluczy:

$hash{"$key1:$key2"} = $value1; # etc 

Answer 2

zrobić to:

{ "$key1\x1F$key2" => $value, ... } 

zwykle z metody pomocnika:

sub getKey() { 
    return join("\x1F", @_); 
} 

{ getKey($key1, $key2) => $value, ... } 

--- - EDIT -----

uaktualniony kod powyżej używać separatora ASCII jednostkę na recommendation from @chepner above

Answer 3

Wykorzystanie: Wiele klucze z pojedynczej wartości w hash mogą być wykorzystane do realizacji 2D matryca lub N-wymiarowa matryca!

#!/usr/bin/perl -w 
use warnings; 
use strict; 
use Data::Dumper; 

my %hash =(); 

my ($a, $b, $c) = (2,3,4); 
$hash{"$a, $b ,$c"} = 1; 
$hash{"$b, $c ,$a"} = 1; 

foreach(keys(%hash)) 
{ 
    my @a = split(/,/, $_); 
    print Dumper(@a); 
} 

Answer 4

Można użyć invisible separator dołączyć współrzędne:

Głównie do matematyki, Niewidzialny Separator (U+2063) zapewnia separator między znakami, gdzie znaki interpunkcyjne lub przestrzeń może zostać pominięta, tak jak w dwóch -indywidualny indeks, taki jak i⁣j.

#!/usr/bin/env perl 

use utf8; 
use v5.12; 
use strict; 
use warnings; 
use warnings qw(FATAL utf8); 
use open qw(:std :utf8); 
use charnames qw(:full :short); 

use YAML; 

my %sparse_matrix = (
    mk_key(34,56) => -1, 
    mk_key(1200,11) => 1, 
); 

print Dump \%sparse_matrix; 

sub mk_key { join("\N{INVISIBLE SEPARATOR}", @_) } 

sub mk_vec { map [split "\N{INVISIBLE SEPARATOR}"], @_ } 

~/tmp> perl mm.pl |xxd 
0000000: 2d2d 2d0a 3132 3030 e281 a331 313a 2031 ---.1200...11: 1 
0000010: 0a33 34e2 81a3 3536 3a20 2d31 0a   .34...56: -1.

Answer 5

Zastosowanie $; niejawnie (lub jawnie) w swoich kluczy skrótu, służących do emulacji wielowymiarowego, tak:

my %hash; 
$hash{$key1, $key2} = $value; # or %hash = ($key1.$;.$key2 => $value); 
print $hash{$key1, $key2} # returns $value 

Można nawet ustawić $; do \ x1F razie potrzeby (domyślnie \ 034, z SUBSEP w awk):

local $; = "\x1F";