Jak scalić definicje CSS w plikach z atrybutami stylu śródliniowego, używając Perla?

Question

Wielu klientów poczty e-mail nie lubi łączonych arkuszy stylów CSS, a nawet osadzonego tagu <style>, ale raczej chce, aby CSS pojawiał się jako atrybuty stylu we wszystkich znacznikach.

• BAD: <link rel=stylesheet type="text/css" href="/style.css">
• Źle: <style type="text/css">...</style>
• działa: <h1 style="margin: 0">...</h1>

Jednak ten atrybut style inline podejście jest prawo ból zarządzać.

Znalazłem narzędzia dla Ruby i PHP, które pobierają plik CSS i kilka oddzielnych znaczników jako dane wejściowe i zwracają wynik scalony - pojedynczy plik znaczników ze wszystkimi CSS przekonwertowanymi na atrybuty stylu.

Szukam rozwiązania Perla dla tego problemu, ale nie znalazłem go na CPAN lub przez przeszukanie Google. Jakieś wskazówki? Ewentualnie, czy istnieją moduły CPAN, które można połączyć, aby osiągnąć ten sam rezultat?

• Ruby http://code.dunae.ca/premailer.web/
• PHP http://www.pelagodesign.com/sidecar/emogrifier/
• Perl?

Answer 1

Nie znam kompletnego, paczkowanego rozwiązania.

CSS::DOM 's compute_style podlega tym samym zastrzeżeniom, co powyżej, emogrifier. Ten moduł w połączeniu z HTML::TokeParser powinien być przydatny do gotowania czegoś.

Aktualizacja: Oto buggy miszmasz rzeczy:

#!/usr/bin/perl 

use strict; 
use warnings; 

use CSS::DOM; 
use File::Slurp; 
use HTML::DOM; 
use HTML::TokeParser; 

die "convert html_file css_file" unless @ARGV == 2; 
my ($html_file, $css_file) = @ARGV; 

my $html_parser = HTML::TokeParser->new($html_file) 
    or die "Cannot open '$html_file': $!"; 

my $sheet = CSS::DOM::parse(scalar read_file $css_file); 

while (my $token = $html_parser->get_token) { 
    my $type = $token->[0]; 
    my $text = $type eq 'T' ? $token->[1] : $token->[-1]; 
    if ($type eq 'S') { 
     unless (skip($token->[1])) { 
      $text = insert_computed_style($sheet, $token); 
     } 
    } 
    print $text; 
} 

sub insert_computed_style { 
    my ($sheet, $token) = @_; 
    my ($tag, $attr, $attrseq) = @$token[1 .. 3]; 
    my $doc = HTML::DOM->new; 

    my $element = $doc->createElement($tag); 

    for my $attr_name (@$attrseq) { 
     $element->setAttribute($attr_name, $attr->{$attr_name}); 
    } 

    my $style = CSS::DOM::compute_style(
     element => $element, user_sheet => $sheet 
    ); 

    my @attrseq = (style => grep { lc $_ ne 'style' } @$attrseq); 
    $attr->{style} = $style->cssText; 

    my $text .= join(" ", 
     "<$tag", 
     map{ qq/$_='$attr->{$_}'/ } @attrseq); 
    $text .= '>'; 

    return $text; 
} 

sub skip { 
    my ($tag) = @_; 
    $tag = lc $tag; 
    return 1 if $tag =~ /^(?:h(?:ead|tml)|link|meta|script|title)$/; 
} 

Answer 2

Można użyć CSS::Inlinerhttp://search.cpan.org/dist/CSS-Inliner/