Bash: Jak mogę zastąpić ciąg przez nową linię w boksie osx?

Question

Często googlam. Chcę tylko, aby ta linia:

echo "Replace <newLine> it by <newLine> NEWLINE <newLine> in my OSX terminal <newLine> and bash script" | sed -e 's/<newLine>/\n/g' 

działa w moim terminalu osx iw moim skrypcie basha. Nie mogę użyć do tego sed? Czy istnieje jeszcze jedno rozwiązanie jednej linii?

Answer 1

Tutaj używa sed

echo "Replace <newLine> it by <newLine> NEWLINE <newLine> in my OSX terminal <newLine> and bash script" | sed 's/<newLine>/\'$'\n/g' 

A oto blogpost wyjaśniając dlaczego - https://nlfiedler.github.io/2010/12/05/newlines-in-sed-on-mac.html

Answer 2

Korzystanie tylko bash:

STR="Replace <newLine> it by <newLine> NEWLINE <newLine> in my OSX terminal <newLine> and bash script" 
$ echo ${STR//<newLine>/\\n} 
Replace \n it by \n NEWLINE \n in my OSX terminal \n and bash script 

$ echo -e ${STR//<newLine>/\\n} 
Replace 
it by 
NEWLINE 
in my OSX terminal 
and bash script 

szybkie wyjaśnienie tutaj - składnia jest podobna do składni zastępczej sed, ale użyć podwójny ukośnik (//), aby wskazać, zastępując wszystkie wystąpienia ciągu. W przeciwnym razie zastępowane jest tylko pierwsze wystąpienie ciągu.

Answer 3

To może pracować dla Ciebie:

echo "Replace <newLine> it by <newLine> NEWLINE <newLine> in my OSX terminal <newLine> and bash script" | 
sed 'G;:a;s/<newLine>\(.*\(.\)\)$/\2\1/;ta;s/.$//' 
Replace 
it by 
NEWLINE 
in my OSX terminal 
and bash script 

EDIT: OSX nie akceptuje wielu poleceń zobacz here

echo "Replace <newLine> it by <newLine> NEWLINE <newLine> in my OSX terminal <newLine> and bash script" | 
sed -e 'G' -e ':a' -e 's/<newLine>\(.*\(.\)\)$/\2\1/' -e 'ta' -e 's/.$//' 
Replace 
it by 
NEWLINE 
in my OSX terminal 
and bash script 

Jeszcze innym sposobem:

echo "Replace <newLine> it by <newLine> NEWLINE <newLine> in my OSX terminal <newLine> and bash script" | 
sed $'s|<newLine>|\\\n|g' 
Replace 
it by 
NEWLINE 
in my OSX terminal 
and bash script